将if then命令输入到将遍历列的vba宏中

Question

I Am trying to make a macros that will look at the hour value of cells in a certain row, sort them based on my if, then, else criteria and produce a result based on this that will loop my column.

So if the hour is <= 15 And >= 11, then result is "Lunch".

I am very new to VBA, but here is what I have so far:

Sub Time_Sorter()

Dim i As Long
Dim result As String

For i = 1 To Rows.count            
    If Hour("J" & i) <= 15 And Hour("J" & i) >= 11 Then
        result = "Lunch"    
    ElseIf Hour("J" & i) <= 16 And Hour("J" & i) >= 17 Then
        result = "Pre-Dinner"    
    ElseIf Hour("J" & i) <= 18 And Hour("J" & i) >= 21 Then
        result = "Dinner"    
    ElseIf Hour("J" & i) <= 22 And Hour("J" & i) >= 23 Then
        result = "Late Night"
    Else
        result = "Other"    
    End If       
Next i

End Sub

I keep getting the message

Run-time error '13': Type mismatch

And I'm not sure how to fix it.

Any insight would be very appreciated!

Answer 1

I think you are after something like the code below.

Iv'e replaced your multiple ElseIf s with a constructed Select Case .

Code

Sub Time_Sorter()

Dim i As Long
Dim result As String

' loop from the first row until last row with data in column ""j"
For i = 1 To Cells(Rows.Count, "J").End(xlUp).Row
    Select Case Hour(Range("J" & i).Value)
        Case 11 To 15
            result = "Lunch"
        Case 16 To 17
            result = "Pre-Dinner"
        Case 18 To 21
            result = "Dinner"
        Case 22 To 23
            result = "Late Night"
        Case Else
            result = "Other"
    End Select
Next i

End Sub