Excel宏的以下VBA代码有什么问题？

Question

The following code is VBA code for an Excel macros. The objective is to read input from the file Impeller_hub.dat and to write it into copy_hub.dat . The error message I received stated that there's a type mismatch, Run-time error '13'. Where is the error and how can it be rectified?

Private Sub fn_write_to_text_Click()
   Dim FilePath As String
   Dim CellData As String
   Dim LastCol As Long
   Dim LastRow As Long

   Dim fso As FileSystemObject
   Set fso = New FileSystemObject
   Dim stream As TextStream
   Dim stream2 As String

   LastCol = ActiveSheet.UsedRange.Columns.Count
   LastRow = ActiveSheet.UsedRange.Rows.Count
    stream2 = "C:\Users\devanandd\Desktop\copy_hub.dat"

   Set stream = fso.OpenTextFile("C:\Users\devanandd\Desktop\Files\NUMECA\Impeller_Hub.dat", stream2, True)

   CellData = ""

   For i = 1 To LastRow
      For j = 1 To LastCol
         CellData = Trim(ActiveCell(i, j).Value)
         stream.WriteLine "The Value at location (" & i & "," & j & ")" & CellData
      Next j
   Next i

   stream.Close
   MsgBox ("Job Done")
End Sub

Answer 1

Something like this works for me (using as much from your code as possible):

Option Explicit
Option Private Module

Private Sub fn_write_to_text_Click()

    Dim FilePath        As String
    Dim CellData        As String
    Dim LastCol         As Long
    Dim LastRow         As Long

    Dim fso             As Object
    Dim stream          As Object
    Dim stream2         As String

    Dim i               As Long
    Dim j               As Long

    Set fso = CreateObject("Scripting.FileSystemObject")

    LastCol = ActiveSheet.UsedRange.Columns.Count
    LastRow = ActiveSheet.UsedRange.Rows.Count
    stream2 = "C:\YOURPATH\Desktop\aaa.txt"

    'Uncomment the next line if you do not have the file
    'Set stream = fso.CreateTextFile(stream2, True)
    Set stream = fso.OpenTextFile(stream2, 8) '8 is ForAppending

    CellData = ""

    For i = 1 To LastRow
        For j = 1 To LastCol
            CellData = Trim(ActiveCell(i, j).value)
            stream.WriteLine "The Value at location (" & i & "," & j & ")" & CellData
        Next j
    Next i

    stream.Close
    MsgBox ("Job Done")

End Sub

The code below would work if you have the file aaa.txt on your desktop. If you do not have it write:

Set stream = fso.CreateTextFile(stream2, True) to create it and delete the line Set stream = fso.OpenTextFile(stream2,8) .

Answer 2

If you want to read from file Impeller_hub.dat and to write to file copy_hub.dat , then you need two TextStream variables, and two separate calls of fso.OpenTextFile : one with second argument ForReading , the other with second argument ForWriting .

Or, if you want to add data to the end of file Impeller_hub.dat , then - as CLR already wrote - the second argument for fso.OpenTextFile should be ForAppending .