希望创建一个Excel用户窗体以根据参数从工作表中提取信息

Question

I have a worksheet with thousands of information on start-end series of machine ID numbers. These are further grouped into years 2012, 2013, 2014, 2015. So in each year there are 2 columns of numbers: start and end. These refer to the start and end of the machinery ID.

   Model     2012           2013          2014        2015
            Start  End    Start  End    Start End   Start End
    XYZ     00123  0800   08015  0834   0654  0756  1320  1390
    ABC     00010  00200  1500   1600    etc...

I am confused how to make a search with userform that will identify the model name, then search for its ID with the table and return the year where that ID falls in.

• Search parameter 1: Match and return the model name typed in the search
• Search parameter 2: Find where the ID is in the entire table

Result: If I type in "XYZ" and the ID number "0756" in the search then that should giving me an answer of 2014.

Answer 1

If we assume the data in the question starts at cell A1 this would be a possible solution.

Sub TestFindYear()
    MsgBox FindYearByModelAndId("XYZ", 755), vbInformation
End Sub

Public Function FindYearByModelAndId(searchModel As String, serachID As Double) As String
    Dim wsData As Worksheet
    Set wsData = ThisWorkbook.Worksheets("Data") 'we assume that the worksheet name to search in is "Data"

    Dim modelRow As Long, lastCol As Long

    'find the row number of the model in column A
    On Error GoTo errorModelNotFound 'throw an error if model was not found
        modelRow = Application.WorksheetFunction.Match(searchModel, wsData.Range("A:A"), 0)
    On Error GoTo 0

    With wsData
        lastCol = .Cells(modelRow, .Columns.Count).End(xlToLeft).Column 'get the last used column of the model row
        Dim i As Long
        For i = 2 To lastCol Step 2 'loop through the columns of the model row
            If serachID >= .Cells(modelRow, i).Value And _
               serachID <= .Cells(modelRow, i + 1) Then 'check if ID is in between start and end
                FindYearByModelAndId = .Cells(1, i).Value 'return the year of row 1
                Exit For
            End If
        Next i
    End With

    If FindYearByModelAndId = vbNullString Then
        FindYearByModelAndId = "ID not found."
    End If

    Exit Function
errorModelNotFound:
    FindYearByModelAndId = "Model not found."
End Function