根据将单元格与用户输入的日期进行比较并跳过空白单元格来删除行

Question

I am looking for a way to remove rows based on the termination date of an employee. I don't want blank cells to be deleted because those employees are still active. I have a text box that pops up and asks for the dates and then show the entered date. Then it is supposed to search column G for any dates prior to the entered date and delete those rows, skipping any row that is blank. I have been searching everywhere for a way to do this but I can't get the Macro to stop deleting every row but the headers. The dates are in column G and it's about 46 rows but that can change.

Sub DateSelectandClean()
    '
    ' DateSelectandClean Macro
    ' User enters date and spreadsheet deletes everything prior to that date, ignoring empty cells.

Application.ScreenUpdating = False

Dim W2Year As Date, N As Long
Dim dt As Date

W2Year = CDate(Application.InputBox(Prompt:="Please enter W2 Year as xx/xx/xxxx Date:", Type:=2))
MsgBox W2Year


N = Cells(Rows.Count, "G").End(xlUp).Row


For i = N To 2 Step -1
dt = Cells(i, 1).Value
    If (Cells(i, 1).Value <> "" And dt < W2Year) Then
        Cells(i, 1).EntireRow.Delete
    End If

Next i
Application.ScreenUpdating = True

End Sub

Sample Data

Answer 1

Your code might be getting an issue in blank date.
I separate the IF so that it won't continue the validation on date.
eg IF "" < #01/01/2017#

Try this, not much changes though:

Sub DateSelectandClean()

' DateSelectandClean Macro
' User enters date and spreadsheet deletes everything prior to that date, ignoring empty cells.

    Application.ScreenUpdating = False
    Dim dateCol, iRow
    Dim W2Year As Date, N As Long
    Dim dt As String

    W2Year = CDate(Application.InputBox(Prompt:="Please enter W2 Year as dd/mm/yyyy Date:", Type:=2))
    MsgBox W2Year

    N = Cells(Rows.Count, "G").End(xlUp).Row
    dateCol = 7
    For iRow = N To 2 Step -1
        dt = Cells(iRow, dateCol).Value
        If (Cells(iRow, dateCol).Value <> "") Then
            If (CDate(dt) < CDate(W2Year)) Then
                Cells(iRow, dateCol).EntireRow.Delete
            End If
        End If
    Next

    Application.ScreenUpdating = True

End Sub

Answer 2

The main issue is you're checking the "A" column for your date info, and deleting based on that. If your dates are in "G", you should check Cells(x,7) , not Cells(x,1) .

Sub DateSelectandClean()
'
' DateSelectandClean Macro
' User enters date and spreadsheet deletes everything prior to that date, ignoring empty cells.

Application.ScreenUpdating = False

Dim W2Year As Date, lastRow As Long, i As Long, dateCol As Long
Dim dt      As Date

dateCol = 7                  ' for column G

Do While W2Year = "00:00:00"
    W2Year = Format(Application.InputBox(Prompt:="Please enter W2 Year as xx/xx/xxxx Date:", Type:=2), "mm/dd/yyyy")
    MsgBox W2Year
Loop

lastRow = Cells(Rows.Count, dateCol).End(xlUp).Row

For i = lastRow To 2 Step -1
    'If Cells(i, dateCol).Value <> "" Then
    If IsDate(Cells(i,dateCol)) Then
        dt = CDate(Format(Cells(i, dateCol).Value, "mm/dd/yyyy"))
        If dt <= W2Year Then
            Cells(i, dateCol).EntireRow.Delete
        End If
    End If
Next i
Application.ScreenUpdating = True
End Sub

I also change the variables from Date to String which allows a little bit of error catching when the user inputs info. You can edit that back if you wish, I was just thinking of a time when someone puts in "wrong" or incorrectly formatted info.