动态SQL输出到临时表

Question

I can successfully run the following code to transpose a data set, and would like to store the output in a temporary table so I can run some code like 'select * from #table' outside the script below and see the results. Any help will be appreciated.

Data:

TimeSeconds TagID Value
1378700244  A1    3.75
1378700245  A1    30
1378700304  A1    1.2
1378700305  A2    56
1378700344  A2    11
1378700345  A3    0.53
1378700364  A1    4
1378700365  A1    14.5
1378700384  A1    144
1378700384  A4    10

Code:

DECLARE @cols NVARCHAR(MAX), @sql NVARCHAR(MAX)

SET @cols = STUFF((SELECT DISTINCT ',' + QUOTENAME(TagID)
            FROM Table1
            ORDER BY 1
            FOR XML PATH(''), TYPE
            ).value('.', 'NVARCHAR(MAX)'),1,1,'')

SET @sql = 'SELECT TimeSeconds, ' + @cols + '
              FROM
            (
              SELECT TimeSeconds, TagID, Value
                FROM table1
            ) s
            PIVOT
            (
              MAX(Value) FOR TagID IN (' + @cols + ')
            ) p'

EXECUTE(@sql)

Answer 1

Well, it is a problem since you don't know in advance the number of columns.
This means you can't define the temporary table with a create table .
I came up with quite an ugly workaround, perhaps somebody else will be able to do it in a more elegant way.
My idea is to create a global temporary table in the dynamic sql script using select...into , and then using another select into to create a local temporary table from that table and drop the global table. (Of course, if you are happy with a global table this step is redundant)

DECLARE @cols NVARCHAR(MAX), @sql NVARCHAR(MAX)

SET @cols = STUFF((SELECT DISTINCT ',' + QUOTENAME(TagID)
            FROM Table1
            ORDER BY 1
            FOR XML PATH(''), TYPE
            ).value('.', 'NVARCHAR(MAX)'),1,1,'')

-- Note I'va added ' INTO ##TEMP'
SET @sql = 'SELECT TimeSeconds, ' + @cols + ' INTO ##TEMP 
              FROM
            (
              SELECT TimeSeconds, TagID, Value
                FROM table1
            ) s
            PIVOT
            (
              MAX(Value) FOR TagID IN (' + @cols + ')
            ) p'

EXECUTE(@sql)


-- Create the local temporary table from the data in the global one
SELECT * INTO #Temp 
FROM ##TEMP
-- Drop the global temporary table
DROP TABLE ##TEMP

Note that if you multiple users might run this script at the same time it's not really a good idea, because of the use of a global temporary table.

Answer 2

IF OBJECT_ID('Tempdb..#Temp') IS NOT NULL
DROP TABLE #Temp

;With cte(TimeSeconds, TagID, Value)
AS
(
SELECT 1378700244,'A1',3.75 Union all
SELECT 1378700245,'A1',30   Union all
SELECT 1378700304,'A1',1.2  Union all
SELECT 1378700305,'A2',56   Union all
SELECT 1378700344,'A2',11   Union all
SELECT 1378700345,'A3',0.53 Union all
SELECT 1378700364,'A1',4    Union all
SELECT 1378700365,'A1',14.5 Union all
SELECT 1378700384,'A1',144  Union all
SELECT 1378700384,'A4',10   
)
SELECT * INTO #temp From cte

DECLARE @cols Nvarchar(max),
        @sql Nvarchar(max),
        @sql2 Nvarchar(max),
        @cols2 Nvarchar(max)


SET @cols = STUFF((SELECT DISTINCT ',' + 'ISNULL('+ TagID +',''0'' )'+' AS '+ QUOTENAME(TagID) FROM #temp
            ORDER BY 1
            FOR XML PATH(''), TYPE
            ).value('.', 'NVARCHAR(MAX)'),1,1,'')


SET @cols2 = STUFF((SELECT DISTINCT ',' +  QUOTENAME(TagID) FROM #temp
            ORDER BY 1
            FOR XML PATH(''), TYPE
            ).value('.', 'NVARCHAR(MAX)'),1,1,'')


SET @sql = 'SELECT TimeSeconds, ' + @cols + ' INTO #Temp1
              FROM
            (
              SELECT TimeSeconds, TagID, Value
                FROM #Temp
            ) s
            PIVOT
            (
              MAX(Value) FOR TagID IN (' + @cols2 + ')
            ) p'

PRINT @sql

SET @sql2='SELECT TimeSeconds,'+ @cols + ' FROM  #temp1'

PRINT @sql2

EXECUTE(@sql)

EXECUTE(@sql2)