Neo4j更新一对多关系

Question

I am trying to update a relationship between two Nodes. The node types are:

1. Role
2. Permission .

The relationship name is

• HAS_PERMISSION .

I would like the query to work for the following two scenarios:

SCENARIO A. Add new relationship

When a new permission name is passed by PUT request to the API, the following should occur:

• STATE : admin-[:HAS_RELATIONSHIP]->create

• PERMISSION PASSED BY REQUEST : ['create', 'update'] (requestPermissions on Query)

• NEXT STATE : admin-[:HAS_RELATIONSHIP]->create and admin-[:HAS_RELATIONSHIP]->update

SCENARIO B : Delete Relationship

• STATE : admin-[:HAS_RELATIONSHIP]->create and admin-[:HAS_RELATIONSHIP]->update

• PERMISSION PASSED BY REQUEST : ['update']

• NEXT STATE : admin-[:HAS_RELATIONSHIP]->update

WITH [1] collects all current permissions by converting it to a list. WITH [2] gets the difference between the current permissions and the permissions passed by the request obtaining the permissions that should be deleted and it converts the current permissions into a list of names (its node structure is {name : 'permission-name'} . WITH [3] gets the difference between the request permissions and the current permissions obtaining the permissions that should be added. Then the nodes are deleted and added accordingly.

The following query does the work ok. It works as expected on Scenario A but on Scenario B it does the job but it does not return anything.

MATCH (role:Role)-[:HAS_PERMISSION]->(permissions:Permission) 
WHERE id(role) = 7
SET role = {name: 'admin'}

WITH COLLECT(permissions) AS permissions, 
    ['update'] AS requestPermissions, 
    role

WITH FILTER(permission IN permissions WHERE NOT permission.name IN 
    requestPermissions) AS toDeletePermissions, 
    REDUCE(values = [], permission in permissions | values + 
       permission.name) as permissionsValues,
    requestPermissions,
    role, 
    permissions

WITH FILTER(permission IN requestPermissions WHERE NOT permission IN 
    permissionsValues) AS toAddPermissions, toDeletePermissions, role, 
    permissions

UNWIND (CASE toDeletePermissions WHEN [] THEN [null] ELSE 
    toDeletePermissions END) as permission
    OPTIONAL MATCH (role)-[rel:HAS_PERMISSION]->(permission)
    DELETE rel

WITH toAddPermissions, permissions, role

UNWIND  (CASE toAddPermissions WHEN [] THEN [null] ELSE 
  toAddPermissions END) AS permission
  MATCH (p:Permission {name: permission})   
  MERGE (role)-[:HAS_PERMISSION]->(p)

WITH role
MATCH (role)-[:HAS_PERMISSION]->(permissions:Permission)
RETURN role, permissions 

Answer 1

If I may simplify your problem, scenario A and B can be converted to scenario C as "Set role's permissions to this list". Like that, you just need to 'clean' the pre-existing relationships and write new ones.

MATCH (role:Role)
WHERE id(role) = 7
SET role = {name: 'admin'}
WITH role, ['update'] as requestPermissions 

// Use optional so that absence of matches doesn't break anything
OPTIONAL MATCH (role)-[rel:HAS_PERMISSION]->(permission:Permission)
WHERE NOT permission.name IN requestPermissions 
DELETE rel

WITH DISTINCT role, requestPermissions
MATCH (permission:Permission)
WHERE permission.name IN requestPermissions
CREATE UNIQUE (role)-[:HAS_PERMISSION]->(permission)

// Return what we set
RETURN role, permission

Much simpler, and less that can go wrong. As for combining DELETE and RETURN in the same query, this can have... weird.. results as the Cypher is one transaction, and the Order the Cypher is done is not guaranteed. So I would recommend only returning the count of deleted items when using DELETE (or at the very least, only return what you have already matched before the DELETE, and deleted items may be empty).