如何使用多个可选匹配来优化Cypher-Query

Question

I have following cypher query with multiple optional matches which can't be run on my machine anymore (Cartesian Product):

match (document:Document)-[*..2]-(relateddocument:Document)
optional match (document)-[:HAS_CATEGORY]->(c:Category)<-[:HAS_CATEGORY]-(relateddocument)
optional match (document)-[:HAS_KEYWORD]->(k:Keyword)<-[:HAS_KEYWORD]-(relateddocument)
optional match (document)-[:HAS_AUTHOR]->(a:Author)<-[:HAS_AUTHOR]-(relateddocument)
with document, relateddocument, collect(c)+collect(k)+collect(a) as similarity
where id(document) = 85182 return relateddocument, similarity order by similarity desc limit 5

Could you please give me a hint how I could optimize this query?

Answer 1

As the other answers indicate, you need to put the WHERE clause as close as possible to the corresponding MATCH , to minimize the number of rows generated by the MATCH .

In addition, you can eliminate the cartesian products caused by all the back-to-back OPTIONAL MATCH clauses by using COLLECT to convert the N rows from each MATCH to 1 row. (The last WITH would be right before the RETURN , and so could be "merged" into the RETURN .)

Also, your ORDER BY similarity DESC clause does not make any sense (and will probably cause an error), since similarity is a collection. You probably meant to use SIZE(similarity) instead of similarity there.

This should be faster:

MATCH (document:Document)-[:HAS_CATEGORY|:HAS_KEYWORD|:HAS_AUTHOR*..2]-(relateddocument:Document)
WHERE ID(document) = 85182
OPTIONAL MATCH (document)-[:HAS_CATEGORY]->(c:Category)<-[:HAS_CATEGORY]-(relateddocument)
WITH document, relateddocument, COLLECT(c) AS cs
OPTIONAL MATCH (document)-[:HAS_KEYWORD]->(k:Keyword)<-[:HAS_KEYWORD]-(relateddocument)
WITH document, relateddocument, cs, COLLECT(k) AS ks
OPTIONAL MATCH (document)-[:HAS_AUTHOR]->(a:Author)<-[:HAS_AUTHOR]-(relateddocument)
RETURN relateddocument, cs+ks+collect(a) as similarity
ORDER BY SIZE(similarity) DESC
LIMIT 5;

Notice that the first MATCH also uses [:HAS_CATEGORY|:HAS_KEYWORD|:HAS_AUTHOR*..2] to filter the relationship types, in case your documents have a lot of relationships with other types. That could further reduce the number of rows generated by the first MATCH , which would reduce the amount of work done by the entire query.

Answer 2

One way to immediately improve it is to move the WHERE id(document) = 85182 straight under the MATCH statement. That should give a major difference if you PROFILE the query.

Regards, Tom

Answer 3

The main problem is that match (document:Document)-[*..2]-(relateddocument:Document) is a Cartesian product between all documents to all documents 2 links away, and the WITH between the match and the id filter tells Cypher not to apply the filter until AFTER it has done all the work. By moving the WHERE id(...) to before the WITH, Cypher will know it is safe to limit (document:Document) to just id 85182, and thus avoid the n^2 match of basically all documents to all documents.

MATCH (document:Document)-[*..2]-(relateddocument:Document)
WHERE id(document) = 85182
WITH document, relateddocument
OPTIONAL MATCH (document)-[:HAS_CATEGORY]->(c:Category)<-[:HAS_CATEGORY]-(relateddocument)
OPTIONAL MATCH (document)-[:HAS_KEYWORD]->(k:Keyword)<-[:HAS_KEYWORD]-(relateddocument)
OPTIONAL MATCH (document)-[:HAS_AUTHOR]->(a:Author)<-[:HAS_AUTHOR]-(relateddocument)
WITH relateddocument, collect(c)+collect(k)+collect(a) as similarity
RETURN relateddocument, similarity 
order by similarity desc 
limit 5