Neo4j / Cypher-获取分层数据并将其转换为树时，如何将可选匹配项与路径相关联？

Question

I'm not sure if that title makes complete sense, but here is what I'm trying to do.

I have the following query that works fine:

MATCH (n:Thing)-[:has_child*0..]->(m) 
WHERE NOT ()-[:has_child]->(n)
WITH n, m 
ORDER BY n.name, m.name 
MATCH p=(n:Thing)-[:has_child*0..]->(m) 
WITH COLLECT(p) AS ps 
CALL apoc.convert.toTree(ps) yield value 
RETURN value

I also have the following query that is also fine which is executed in another part of the application (because I can't figure out how to to it at once):

MATCH (n:Thing {name: {nameParam}})<-[:has_child*]-(m:Thing 
      {btogstate: {btogstateParam}})
RETURN m

So what is happening in the second query is that it is looking up the chain to see if btogstate is set to a certain value. What I'd like to do is combine the two.

Does anyone know how I could put the second query into the first one so that when accessing the tree (value) that I would know that that record has or does not have the value I was querying for?

Hopefully that makes sense. I know this is probably not a common issue.

Update to clarify question

Let's say we have some hierarchical data that looks like this, and in the DB it looks like (pseudo) (asdf)-[:has_child]->(qwer)-[:has_child]-> and so on:

--asdf
   -qwer
     -wert
       -erty
--rtyu
   -yuio

Now let's say that we need to know if 'erty' has anything up it's relational chain that has the property of btogstate set to false, and let's say that qwer does in fact have this property set to false.

Then the question is: how can the query be structured in a way that when you read the results (value) you know that 'erty' had a parent that had btogstate set to false?

Answer 1

Are you searching something like that :

MATCH p=(n:Thing)-[:has_child*0..]->(m) 
WHERE NOT ()-[:has_child]->(n) AND
      any(node IN NODES(p) WHERE node.btogstate = $btogstateParam )
WITH COLLECT(p) AS ps 
CALL apoc.convert.toTree(ps) yield value 
RETURN value

Like Tom said, I have done a refactoring on the first part of your query (combine the path and the where clause).

And to combine your 2 queries, I have used the any function.

Cheers.

Answer 2

What you are actually looking for - I think - is setting a temporary property that will only show-up in your result. Now, you could actually do that (outside Neo4j) when processing the tree after doing the query. If you want to do it in Neo4j itself the way I would do it is with three queries :

MATCH (m:Thing)<-[:HAS_CHILD*0..]-(n:Thing {btogstate: "true"})
WHERE m <> n
SET m.hasit = "yes";

MATCH (n:Thing)-[:HAS_CHILD*0..]->(m) 
WHERE NOT ()-[:HAS_CHILD]->(n)
WITH n, m 
ORDER BY n.name, m.name
MATCH p=(n)-[:HAS_CHILD*0..]->(m)
WITH COLLECT(p) AS ps
CALL apoc.convert.toTree(ps) yield value 
RETURN value;

MATCH (m:Thing)
REMOVE m.hasit;

A Cypher expert (please chime in :-) can probably do this in one statement. I think that would however not improve the readability.

Hope this helps, Tom