当被另一个存储过程调用时，存储过程未返回正确的值

Question

I'm having issues executing a stored procedure within another stored procedure. Basically, when I execute my stored procedure by itself, it works just fine, and inserts and returns the correct values. However, when I call the same stored procedure within another stored procedure, with the same input as when I tried it manually, it doesn't insert anything, and doesn't return the correct value. Is there something weird going on with how the variables are handled? Or is something else going wrong? See my code below.

The first procedure:

ALTER PROCEDURE [dbo].[createOrgLevel]
    @name varchar(255),
    @level int,
    @parentid bigint,
    @newid bigint OUTPUT
AS
    SET NOCOUNT ON;
    -- Check to see if it exists
    SELECT @newid = [id] from dbo.[Org 3]
        WHERE
        [Name] = @name and
        [Parent ID] = @parentid
        IF @newid IS NULL
        -- If it doesn't exist, insert
            BEGIN
                INSERT INTO [dbo].[Org 3]
                   ([Parent ID]
                   ,[Name]
                   ,[Level])
                VALUES
                   (@parentid
                   ,@name
                   ,@level)
                SET @newid = @@identity
            END
END

An abbreviated version of the procedure calling it:

ALTER PROCEDURE [dbo].[createOrg]
    @level1 nvarchar(255),
    @level2 nvarchar(255),
    @level3 nvarchar(255),
    @level4 nvarchar(255),
    @level5 nvarchar(255),
    @level6 nvarchar(255),
    @level7 nvarchar(255),
    @level8 nvarchar(255),
    @orgid bigint OUTPUT
AS
BEGIN
    SET NOCOUNT ON;

    DECLARE
    @parid bigint,
    @curname nvarchar(255)
    DECLARE
    @levels table (num int, name nvarchar(255))
    INSERT @levels(num, name) values (1,@level1),(2,@level2),(3,dbo.@level3),
    (4,@level4),(5,@level5),(6,@level6),(7,@level7),
    (8,@level8)

    BEGIN
        BEGIN TRY
            SET @curname = @level1
            EXEC dbo.createOrgLevel @name = @curname, @level = 1, @parentid = 0, @newid = @orgid OUTPUT
            SET @parid = @orgid
        END TRY
        BEGIN CATCH
            SET @orgid = NULL
            RETURN -1
        END CATCH

        DECLARE @cnt INT = 2;

        WHILE @cnt < 9
        BEGIN
            BEGIN TRY
                SELECT @curname = name FROM @levels WHERE num = @cnt
    -----------------------------------
    -- This is where it is executed, and not inserting/returning the correct value. It keeps
    -- returning the value from the previous 'loop', and not inserting anything. It's not
    -- entering the Catch, though.

                EXEC dbo.createOrgLevel @name = @curname, @level = @cnt, @parentid = @parid, @newid = @orgid OUTPUT

    -----------------------------------
                SET @parid = @orgid
            END TRY
            BEGIN CATCH
                RETURN 1
            END CATCH
            SET @cnt = @cnt + 1
        END
    END
END

Again, if I manually execute the first procedure, it correctly inserts the Org Level, and returns the ID. However, when it is called in the second procedure, it doesn't insert any new Org Levels, and just returns the ID of the first Org Level it finds (the parent level for all Orgs, that I manually inserted).

I have tried troubleshooting this issue, by printing out all the parameters before the procedure is executed within the second, and they are exactly the same as when I try it manually. I also checked to see if errors where occurring, and it was entering the catch statement, but it wasn't. Can anyone help me out here?

Answer 1

Yes, this is because you refactor @newid variable in each iteration and it's value from last run is still stored in it on each consecutive run.

Your problem is here actually:

   SELECT @newid = [id] from dbo.[Org 3]
        WHERE
        [Name] = @name and
        [Parent ID] = @parentid

@newid already has a value, and since the query does not return anything, value is not overrided with NULL but remains from last time.

What you should do is either:

• Set @newid to NULL at the start of your inner stored procedure or
• Use different name for variable to check if org exists then the one you are returning to output (set the return value at the end of SP) or

• You can rewrite SELECT to SET which would overwrite value with NULL if nothing is returned

    SET @newid = (SELECT id FROM dbo.[Org 3]..)