带有对象所需的VBA代码错误

Question

Code has error. When I debug, it shows the error of last line.

Sub test()
    WB_Master = ActiveWorkbook.Name
    Dim ra As Range
    open file
    Workbooks.Open FileName:="X:\Projects\RPOC\Comparison\book1.xlsx"
    WB_Source = ActiveWorkbook.Name
    Workbooks(WB_Source).Activate
    Worksheets("sheet1").Activate
    ' set value to ra. Is it correct?
    Set ra = Range("c2")

    Workbooks(WB_Source).Close SaveChanges:=False


    Workbooks(WB_Master).Activate

    Worksheets("sheet1").Activate

    Set Range("k2").Value = ra.Value

End Sub

Answer 1

You can't Set a Value - you should only use the Set keyword when assigning an object reference. (Eg your Set ra = Range("c2") is assigning a reference to Range("c2") to your object ra .)

So change

Set Range("k2").Value = ra.Value

to

Range("k2").Value = ra.Value

---

Because you are also closing the workbook that contains the range referred to by your ra variable before you use it, you will also have problems. I have refactored your code to get around that issue:

Sub test()
    Dim WB_Source As Workbook
    Dim WB_Master As Workbook

    Set WB_Master = ActiveWorkbook
    Set WB_Source = Workbooks.Open(FileName:="X:\Projects\RPOC\Comparison\book1.xlsx")

    WB_Master.Worksheets("sheet1").Range("k2").Value = _
        WB_Source.Worksheets("sheet1").Range("c2").Value

    WB_Source.Close SaveChanges:=False
End Sub

(Note: I changed your WB_Source and WB_Master variables from being Variant/String to being Workbook .)