使用单独的数据文件读取Groovy中的变量

Question

I am trying to separate variables data from my actual script groovy file.

def test = [a,b,c]
def test2 = ['foo': [a,x,y], 'bar': [q,w,e]]


def function(String var){}
def function2 {
test.each
{ 
    item ->
print test


}
}

since my values in the variables are changing constantly but not the script. How do I make my groovy read a variable file and load it during the runtime?

I want it to look something like this maybe.

variables.properties
def test = [a,b,c]
def test2 = ['foo': [a,x,y], 'bar': [q,w,e]]

main.groovy

load ( variable.properties)

def function(String var){}
def function2 {
test.each
{ 
    item ->
print test


}
}

Answer 1

In Groovy, it is possible to evaluate data as Groovy code. This is a powerful technique. It is arguably a bit much for your goals, but would work.

Consider this config.data file (it is a Groovy file but can be named anything):

test = ['a','b','c']
test2 = ['foo': ['a','x','y'], 'bar': ['q','w','e']]

and the App.groovy file. It sets up a Binding of variables in a GroovyShell . The Config is evaluated inside the shell, and we can reference the variables in the main app.

def varMap = [:]
varMap["test"] = [] 
varMap["test2"] = [:] 

def binding = new Binding(varMap)
def shell = new GroovyShell(binding)

def function2 = { test, test2 ->
    test.each { println "test item: ${it}" }
    test2.each { println "test2 item: ${it}" }
}

// ------ main

// load Config and evaluate it
def configText = new File(args[0]).getText()
shell.evaluate(configText)

def test = varMap["test"] 
def test2 = varMap["test2"] 

function2(test, test2)

an example usage:

$ groovy App.groovy config.data 
test item: a
test item: b
test item: c
test2 item: foo=[a, x, y]
test2 item: bar=[q, w, e]