如何将字符串中哈希的所有键替换为其值？

Question

I am coding a script with a variable system. The program uses a hash with a value for each keyword, but I don't know how to continue when it comes to replacing all keywords in a string.

The code of the replacement looks like:

while ( ($key, $value) = each %variables_hash ) {
    if ( -1 != index($CMD, $key) ) {
        # Here should be the code that I cant think how to do
    }
}

$CMD is the input string, and %variables_hash is the hash that contains the variabless

Answer 1

You can use substr to replace the substring. I used while instead of if so you can replace multiple occurrences. length $key is used to determine the length of the substring to replace.

#!/usr/bin/perl
use warnings;
use strict;

my %variables_hash = (
    _number => 123,
    _name   => 'John Smith',
);

my $CMD = 'INSERT INTO customers (name, code) VALUES("_name", _number)';


while (my ($key, $value) = each %variables_hash) {
    while (-1 != ( my $pos = index $CMD, $key )) {
        substr $CMD, $pos, length $key, $value;
    }
}

print $CMD, "\n";

Another option would be to use substitution (see perlop ), or a Template (eg Template ).

Substitution:

my $regex = join '|', map quotemeta, keys %variables_hash;

$CMD =~ s/($regex)/$variables_hash{$1}/g;

Note that if one variable name is a substring of another, you probably want to process them from the longest to the shortest (the same applies to the substr solution); so you might need to say

map quotemeta, sort { length $b <=> length $a } keys %variables_hash;

Template:

Note that variables can't start with underscores, but they aren't needed, as the variables are included in template tags, so you won't accidentally replace name when it refers to the column name.

use Template;

my %variables_hash = (
    number => 123,
    name   => 'John Smith',
);

my $CMD = 'INSERT INTO customers (name, code) VALUES("[% name %]", [% number %])';

my $template = 'Template'->new;
$template->process(\$CMD, \%variables_hash);

Answer 2

If you're going to be a Perl programmer, then you need to read the Perl FAQ. This is from perlfaq4.

How can I expand variables in text strings?

(contributed by brian d foy)

If you can avoid it, don't, or if you can use a templating system, such as Text::Template or Template Toolkit, do that instead. You might even be able to get the job done with sprintf or printf :

  my $string = sprintf 'Say hello to %s and %s', $foo, $bar; 

However, for the one-off simple case where I don't want to pull out a full templating system, I'll use a string that has two Perl scalar variables in it. In this example, I want to expand $foo and $bar to their variable's values:

  my $foo = 'Fred'; my $bar = 'Barney'; $string = 'Say hello to $foo and $bar'; 

One way I can do this involves the substitution operator and a double /e flag. The first /e evaluates $1 on the replacement side and turns it into $foo . The second /e starts with $foo and replaces it with its value. $foo , then, turns into 'Fred', and that's finally what's left in the string:

  $string =~ s/(\\$\\w+)/$1/eeg; # 'Say hello to Fred and Barney' 

The /e will also silently ignore violations of strict, replacing undefined variable names with the empty string. Since I'm using the /e flag (twice even!), I have all of the same security problems I have with eval in its string form. If there's something odd in $foo , perhaps something like @{[ system "rm -rf /" ]} , then I could get myself in trouble.

To get around the security problem, I could also pull the values from a hash instead of evaluating variable names. Using a single /e , I can check the hash to ensure the value exists, and if it doesn't, I can replace the missing value with a marker, in this case ??? to signal that I missed something:

  my $string = 'This has $foo and $bar'; my %Replacements = ( foo => 'Fred', ); # $string =~ s/\\$(\\w+)/$Replacements{$1}/g; $string =~ s/\\$(\\w+)/ exists $Replacements{$1} ? $Replacements{$1} : '???' /eg; print $string;