如何通过IO操作运行列表

Question

So I'm writing a program that checks for every line of a .txt file whether it is a palindrome or not,

import System.IO

main :: IO()
main = do {
content <- readFile "palindrom.txt";
print content;
print (lines content);
singleWord (head (lines content));
return ();
}

palindrom :: [Char] -> Bool
palindrom a = a == reverse a

singleWord :: [Char] -> IO()
singleWord a = do { 
print (length a);
print (show (palindrom a));
}

But instead of singleWord (head (lines content)) I need to run the singleWord through the entire list.

The problem is that with map or normal list comprehension I always get a ton of varying errors all to do with lines content (which should be an array of Strings or IO Strings) apparently always being the type I don't want (I've tried messing around with type declarations on that forever, but it keeps being the wrong type, or the right one but in an extra array-layer or whatever).

My last attempt is to walk through the array with recursion, with this little extra code:

walkthrough [] = []
walkthrough x = do { singleWord head x; walkthrough (tail x) }

which I can't typecast correctly no matter what.

It's supposed to replace the singleWord (head (lines content)) in main , and if I try anything with typeclassing, like

walkthrough :: [[Char]] -> [[Char]]
walkthrough [] = ["Hi"]
walkthrough x = do { singleWord head x; walkthrough (tail x) }

I get

Couldn't match type `IO' with `[]'
      Expected type: [()]
        Actual type: IO ()

or some other stuff that won't fit together.

Answer 1

You're looking for a function called mapM_ .

main :: IO ()
main = do {
  content <- readFile "palindrom.txt";
  mapM_ singleWord (lines content);
};


palindrome :: [Char] -> Bool
palindrome a = (a == reverse a)

singleWord :: [Char] -> IO()
singleWord a = do {
  let {
    adverb = (if palindrome a then " " else " not ");
  };
  putStrLn  (a ++ " is" ++ adverb ++ "a palindrome.");
};

Answer 2

That should've been

walkthrough [] = return ()                    -- this is the final action
walkthrough x  = do { singleWord (head x)     -- here you missed the parens 
                    ; walkthrough (tail x) }

or better yet,

walkthrough []     = return () 
walkthrough (x:xs) = do { singleWord x        -- can't make that mistake now!
                        ; walkthrough xs}

and call it as walkthrough (lines content) in your main do block.

As others have pointed out, walkthrough is the same as mapM_ singleWord .

You could also write it with a list comprehension,

walkthrough xs = sequence_ [ singleWord x | x <- xs]

sequence_ :: Monad m => [ma] -> m () turns a list of actions into a sequence of actions discarding their results and producing the () in the end: sequence_ = foldr (>>) (return ()) . And sequence_ (map f xs) === mapM_ f xs , so it all ties up in the end.

Answer 3

Use mapM_ singleWord (lines content) . For the sake of simplicity, think of mapM_ as.

mapM_ :: (a -> IO ()) -> [a] -> IO ()