如何查找工作簿表的最大行-VBA

Question

I want to get the data from the workbook which contain the multiple sheets and dont know which sheet having the data. So need to check the used rows count of the every sheet of the workbook and activate the sheet which contain maximum used rows for getting the data. struct with below code and any suggestion would appreciate.

Sub Maxdatasheet()
Dim wscount As Integer
Dim myArray() As Variant

wscount = ActiveWorkbook.Worksheets.Count

  For i = 1 To wscount
    myArray(i) = Worksheets(i).UsedRange.Rows.Count
    Next
    'need to activate the maximus rows of the sheet
End Sub

Answer 1

A few changes:
- No array, keeping track of what sheet had the maximum instead
- Changed to For Each (even though your code was perfectly fine in that aspect)

Sub Maxdatasheet()
    Dim ws As Worksheet
    Dim MaxRowSheet As Worksheet
    Dim MaxRowCount As Long    ' Do not use Integer, may be too small and cause overflow

    wscount = ActiveWorkbook.Worksheets.Count

    MaxRowCount = 0

    For Each ws In ActiveWorkbook.Worksheets
        If ws.UsedRange.Rows.Count > MaxRowCount Then
            MaxRowCount = ws.UsedRange.Rows.Count
            Set MaxRowSheet = ws
        End If
    Next
    MaxRowSheet.Activate
End Sub

Answer 2

To get count of used rows from each sheet-

Sub Maxdatasheet()
Dim wscount As Integer
Dim myArray() As Variant

wscount = ActiveWorkbook.Worksheets.Count
ReDim myArray(1 To wscount)

  For i = 1 To wscount
    myArray(i) = Worksheets(i).UsedRange.Rows.Count
    Debug.Print myArray(i)
  Next
End Sub

Answer 3

Here is a little code I wrote for myself some time ago. It counts all the row numbers of all Worksheets and displays them seperately in a MsgBox (the total sum ist also being displayed).

Sub Datensätze_zählen()
'
' Datensätze_zählen Makro
' Zählt alle Datensätze, aller Blätter einer Excel-Datei und gibt diese in einer MsgBox aus
'

Dim all_rows As Long
Dim sheet_row As String
Dim all_array() As String
Dim max_row As Long

If ActiveWorkbook.Sheets.Count > 1 Then
    ReDim all_array(ActiveWorkbook.Sheets.Count)
    For i = 1 To ActiveWorkbook.Sheets.Count
        ActiveWorkbook.Sheets(i).Activate
        sheet_row = ActiveSheet.name & " " & CStr(ActiveSheet.Cells(ActiveSheet.Rows.Count, "A").End(xlUp).row) - 1 ' wenn es keine Überschrift gibt, dann ohne "- 1"
        all_rows = all_rows + ActiveSheet.Cells(ActiveSheet.Rows.Count, "A").End(xlUp).row - 1 ' wenn es keine Überschrift gibt, dann ohne "- 1"
        all_array(i - 1) = sheet_row
    Next i
    MsgBox (Join(all_array, vbCrLf) & vbCrLf & all_rows)
ElseIf ActiveWorkbook.Sheets.Count = 1 Then
    ActiveWorkbook.Sheets(1).Activate
    MsgBox (ActiveSheet.Cells(ActiveSheet.Rows.Count, "A").End(xlUp).row) - 1 ' wenn es keine Überschrift gibt, dann ohne "- 1"
Else
    MsgBox ("In der ausgewählten Excel-Datei ist kein Worksheet vorhanden.")
End If
Erase all_array
End Sub

Hope that that is what you were looking for

Answer 4

Function CountRow(ColumnName As String, ws as Worksheet) As Long
    CountRow = ws.Range(ColumnName& "65536").End(xlUp).row
End Function  

Sub SelectMAX()  
    Dim ws as Worksheet, max as Worksheet
    max = ThisWorkbook.Worksheet(1)
    For Each ws in ThisWorkbook.Worksheets
        if CountRoW("A", ws) > CountRow("A", max) then max = ws
    Next  
    max.Activate
End Sub

Hope this helps.
PS You can change "A" to any other column if you need.