Excel查找名称的公式拆分字符串

Question

I'm trying to split a list of names, They in the form of:

Surname, Title. Firstname (Nickname)

Jonesy, Mr. Cheese (Edam)
Bukowski, Mrs. Gertrude (Gerti)

I need to put them into Firstname Surname

It should be easy to pick up the Firstname: Two characters after the dot of Title up to the space before the left bracket of Nickname. Only my excel formula doesn't give me what I want.

A1 Smith, Mr. Andrew (Andy)
A2 =MID(A1,1,Find(" ",A1)-2)
A3 =MID(A1,Find(".",A1)+2, Find("(",A1)+1)

Only for A3 I get:

Andrew (Andy)

Instead of just the name Andrew

I'll add the caveat that I need the formula to refer to the name cell and not an cell with temp data to be referenced (ie an interim cell)

I can't see the woods for the trees on this one. Need to call in a bigger brain.

Answer 1

Assuming a data setup where headers are in row 1, with your "Complete Name" in column A starting in row 2, like so:

In cell B2 and copied down is this formula to get the first name:

=MID(A2,FIND(".",A2)+2,FIND("(",A2)-FIND(".",A2)-3)

In cell C2 and copied down is this formula to get the last name:

=LEFT(A2,FIND(",",A2)-1)

Answer 2

You can use this single formula to get the Firstname Surname :

=TRIM(MID(A1,SEARCH(".",A1)+1,SEARCH("(",A1)-SEARCH(".",A1)-1))&" "&MID(A1,1,FIND(" ",A1)-2)

Answer 3

Pretty Simple I think....(Famous last words).

You had:

A1 = Smith, Mr. Andrew (Andy)
A2 =MID(A1,1,Find(" ",A1)-2)
A3 =MID(A1,Find(".",A1)+2, Find("(",A1)+1)

I replaced the A# Find "(" with " " and it worked.

A1 = Smith, Mr. Andrew (Andy)
A2 =MID(A1,1,Find(" ",A1)-2)
A3 =MID(A1,Find(".",A1)+2, Find(" ",A1)+1)

This will only work if you have a single Firstname though. A name like Bobby Joe or Billy Bob will cut off at Bobby and Billy.