运行VBA宏以触发不同工作表中的宏

Question

The situation is like this: I have 40 worksheets embedded with same Macros called RetrieveNumbers . The end results in 40 sheets will be different based upon various parameters in each worksheet.

To update the numbers, I manually click the macro buttons to retrieve numbers in the 40 worksheets. As a result of that, I'm sick of it. To simplify the testing, I only use two sheets(Sheet1, Sheet2) to test if, by clicking a Macro named RunAll, it would run through the two Macros.

Surely, I have FAILED.

I have tried :

1. application.run

2. call

Two scenarios I tried:

1. I hit F5 as I was in the RunAll window and my other screen on the Sheet1 worksheet . It runs perfectly and yet it runs twice in Sheet1 rather than going to Sheet2.

2. I hit F5 as I was in the RunAll window and my another screen on the RunAll worksheet . After clicking it, I went back to see if there were any numbers. And surely, there weren't.

I thought the Macro would go to Sheet2 and then run Macro Retrivenumbers2. But it didn't. It stayed at the current worksheet. Please give me some guidance on how to run the next sheets I want. Let me know if I need to clarify more on this question.

The Macro RetrieveNumbers
(Since the Macro RetrieveNumbers2 is as same as RetrieveNumbers1, I don't include it)

Sub RetrieveNumbers1()

Dim NumberFiles As Integer, FilesVisited As Integer, RowNumber As Integer
Let NumberFiles = ActiveSheet.Cells("2", "A").Value
Let FilesVisited = 0                            'start from 0
Let RowNumber = 4                            'start from column B


If NumberFiles > 30 Then
    MsgBox "Don't try to retrieve numbers from more than 30 files at a time!"
Else
    For FilesVisited = 1 To NumberFiles

    'Open files, get path, file, tab name and cells
    Dim PathFileOpen As String, NameFileOpen As String, NameTab As String, FileDir As String
    Let PathFileOpen = ActiveSheet.Cells(RowNumber, "A").Text
    Let NameFileOpen = ActiveSheet.Cells(RowNumber, "B").Text
    Let NameTab = ActiveSheet.Cells(RowNumber, "C").Text

    Dim N As Integer, Cell As String, NumberYears As String, FullLink As String
    NumberYears = ActiveSheet.Cells("2", "B").Value
    For N = 4 To NumberYears + 3
        Cell = ActiveSheet.Cells(RowNumber, N).Text
        FullLink = "(=)'" & PathFileOpen & "\[" & NameFileOpen & ".xlsm]" & NameTab & "'!" & Cell
        ActiveSheet.Cells(RowNumber, N + 13).Value = FullLink
    Next N
    RowNumber = RowNumber + 1
Next FilesVisited
End If

ActiveSheet.Range("A1").CurrentRegion.Replace What:="(=)", Replacement:="=", _
LookAt:=xlPart, SearchOrder:=xlByRows, MatchCase:=False, 
SearchFormat:=False, ReplaceFormat:=False

End Sub

The Macro RunAll

Sub runall()

Call Sheet1.RetrieveNumbers1
Call Sheet2.RetrieveNumbers2

End Sub

Clear Example of the file Working file example

Answer 1

There's a fair amount wrong with your code. As @PGCodeRider said in his answer - have one procedure that runs on all sheets. His code has the loop within the procedure.

This code uses a separate procedure to cycle through the sheets and passes a reference to the sheet to the RetrieveNumbers procedure.
I've replaced all instances of ActiveSheet (reference to the ActiveSheet) with wrkSht (reference to the sheet that the RunAllSheets procedure passes).
All Dims have been moved to the top of the code as they only need declaring once and not on each loop (you change the value the variables hold on each loop, but no need to declare them again).

Sub RunOnAllSheets()

    Dim wrkSht As Worksheet

    For Each wrkSht In ThisWorkbook.Worksheets
        Select Case wrkSht.Name
            Case "Sheet1", "Sheet2"
                'Do nothing.
            Case Else
                'For all other sheets execute the RetrieveNumbers procedure
                'and pass the wrkSht variable to it.
                RetrieveNumbers wrkSht
        End Select
    Next wrkSht

End Sub

Sub RetrieveNumbers(wrkSht As Worksheet)

    Dim NumberFiles As Integer, FilesVisited As Integer, RowNumber As Integer
    'You only need to declare these once.
    Dim PathFileOpen As String, NameFileOpen As String, NameTab As String, FileDir As String
    Dim N As Integer, Cell As String, NumberYears As String, FullLink As String

    'No need to use 'LET' it's a left-over from the days of Sinclair Basic
    'ok, maybe not.... but it's an old way of doing it.
    NumberFiles = wrkSht.Cells("2", "A").Value
    FilesVisited = 0                         'start from 0
    RowNumber = 4                            'start from column B


    If NumberFiles > 30 Then
        MsgBox "Don't try to retrieve numbers from more than 30 files at a time!"
    Else
        For FilesVisited = 1 To NumberFiles

            'Open files, get path, file, tab name and cells

            PathFileOpen = wrkSht.Cells(RowNumber, "A").Text
            NameFileOpen = wrkSht.Cells(RowNumber, "B").Text
            NameTab = wrkSht.Cells(RowNumber, "C").Text


            NumberYears = wrkSht.Cells("2", "B").Value
            For N = 4 To NumberYears + 3
                Cell = wrkSht.Cells(RowNumber, N).Text
                FullLink = "(=)'" & PathFileOpen & "\[" & NameFileOpen & ".xlsm]" & NameTab & "'!" & Cell
                wrkSht.Cells(RowNumber, N + 13).Value = FullLink
            Next N
            RowNumber = RowNumber + 1
        Next FilesVisited
    End If

    wrkSht.Range("A1").CurrentRegion.Replace What:="(=)", Replacement:="=", _
        LookAt:=xlPart, SearchOrder:=xlByRows, MatchCase:=False, _
        SearchFormat:=False, ReplaceFormat:=False

End Sub

---

Edit, after accepted as answer:

This method only references the sheet twice. Once to pull the link info, and once more to put the final formula back on the sheet.

Sub RunOnAllSheets()

    Dim wrkSht As Worksheet

    For Each wrkSht In ThisWorkbook.Worksheets
        'Have removed the Select Case statement so it looks at all sheets.
        RetrieveNumbers wrkSht
    Next wrkSht

End Sub

Sub RetrieveNumbers(wrkSht As Worksheet)

    Dim NumberFiles As Long, FilesVisited As Long
    Dim vCellValues As Variant, vLinkValues() As Variant
    Dim FullPath As String
    Dim x As Long

    With wrkSht
        'Get the last row number that contains data in column N.
        NumberFiles = .Cells(.Rows.Count, "N").End(xlUp).Row

        If NumberFiles - 3 > 30 Then
            MsgBox "Don't try to retrieve numbers from more than 30 files at a time!"
        Else
            'Pass the cell values to an array.
            vCellValues = .Range("A4:C4")

            'Create the full path excluding the cell reference.
            FullPath = "='" & vCellValues(1, 1) & "[" & vCellValues(1, 2) & "]" & vCellValues(1, 3) & "'!"

            'Create an array of full path & cell references.
            ReDim vLinkValues(1 To NumberFiles - 3) 'Set the array size.
            For x = 1 To NumberFiles - 3
                vLinkValues(x) = FullPath & .Cells(x + 3, "N")
            Next x

            'Paste the array back to the sheet.
            .Range(.Cells(4, "N"), .Cells(NumberFiles, "N")).Formula = vLinkValues
        End If

    End With

End Sub  

Note: This assumes your path is just in cell A4:C4, as indicated by the code vCellValues = .Range("A4:C4") (I'm not sure this is the case now).
If your paths are on each row matching the cell values you'll need to:

• Change vCellValues = .Range("A4:C4") to
  vCellValues = .Range(.Cells(4, 1), .Cells(NumberFiles, 3))
• Remove the FullPath='.... line.
• Change vLinkValues(x) = FullPath & .Cells(x + 3, "N") to
  vLinkValues(x) = "='" & vCellValues(x, 1) & "[" & vCellValues(x, 2) & "]" & vCellValues(x, 3) & "'!" & .Cells(x + 3, "N")

Answer 2

Try running a loop through all of the sheets in the workbook? Also make sure you run this in a module in your vba editor. Not your sheet code.

Sub RetrieveNumbers1()

Dim WS As Worksheet
'loop that goes through all sheets in your workbook. Where you used to have
'activesheet, I changed to ws
For Each WS In ThisWorkbook.Sheets


Dim NumberFiles As Integer, FilesVisited As Integer, RowNumber As Integer
Let NumberFiles = WS.Cells("2", "A").Value
Let FilesVisited = 0                            'start from 0
Let RowNumber = 4                            'start from column B


If NumberFiles > 30 Then
    MsgBox "Don't try to retrieve numbers from more than 30 files at a time!"
Else
    For FilesVisited = 1 To NumberFiles

    'Open files, get path, file, tab name and cells
    Dim PathFileOpen As String, NameFileOpen As String, NameTab As String, FileDir As String
    Let PathFileOpen = WS.Cells(RowNumber, "A").Text
    Let NameFileOpen = WS.Cells(RowNumber, "B").Text
    Let NameTab = WS.Cells(RowNumber, "C").Text

    Dim N As Integer, Cell As String, NumberYears As String, FullLink As String
    NumberYears = WS.Cells("2", "B").Value
    For N = 4 To NumberYears + 3
        Cell = WS.Cells(RowNumber, N).Text
        FullLink = "(=)'" & PathFileOpen & "\[" & NameFileOpen & ".xlsm]" & NameTab & "'!" & Cell
        WS.Cells(RowNumber, N + 13).Value = FullLink
    Next N
    RowNumber = RowNumber + 1
Next FilesVisited
End If


ws.Range("A1").CurrentRegion.Replace What:="(=)", Replacement:="=", _
LookAt:=xlPart, SearchOrder:=xlByRows, MatchCase:=False,
SearchFormat:=False, ReplaceFormat:=False

'restarts on the next ws
Next WS

End Sub