Neo4j Cypher to C＃如何基于参数值与其他节点创建不同的关系

Question

I am trying to create something like this:

Match (rt:Root{Name:root})
Match (o:Organization{orgName:"Org1"}) 
create (u:User{FirstName:"User1", UserRole:"is_member"}) 
CASE  
When u.UserRole="is_member" Then Create (u) -[:"is_member"] -> (o) 
ELSE u.UserRole="is_guest" Then Create (u) -[:"is_guest"] -> (o)
ELSE u.UserRole="is_admin" Then Create (u) -[:"is_admin"] -> (rt)

So depending on UserRole, different relationships will be created between the user and other nodes. For some reason, this is not working in Neo4j and also what would be the equivalent in C#

Thank you!

Answer 1

You have several syntax errors.

The following query should work (note: I opted to use MERGE instead of CREATE to avoid creating duplicates in case you repeat the same query):

MATCH (rt:Root{Name:root}), (o:Organization{orgName:"Org1"})
MERGE (u:User{FirstName:"User1", UserRole:"is_member"})
WITH rt, o, u,
  CASE u.UserRole
    WHEN "is_member" THEN {m: [1]}
    WHEN "is_guest"  THEN {g: [1]}
    WHEN "is_admin"  THEN {a: [1]}
  END AS todo
FOREACH(x IN todo.m | MERGE (u) -[:is_member]-> (o) )
FOREACH(x IN todo.g | MERGE (u) -[:is_guest]->  (o) )
FOREACH(x IN todo.a | MERGE (u) -[:is_admin]->  (rt) )

A CASE expression can only generate variables -- it cannot do operations like CREATE or MERGE . Although the above query also contains a CASE clause, it just generates a todo variable whose value is either an object or NULL (if none of the WHEN tests are satisfied).

Unlike a CASE expression, a FOREACH clause can perform CREATE or MERGE operations. So, the above query has 3 of them -- but at most one of them will actually perform a MERGE , since a FOREACH(x IN todo.foo | ...) clause does nothing unless todo.foo exists and is a non-empty list. (We don't need to use the x variables, so they are ignored.)

Also: The APOC procedure apoc.do.case was recently added, and theoretically could be used instead of the above CASE and FOREACH approach.