如何在Excel表格中搜索文本，然后删除整个行？

Question

I need a macro that takes the inputed text from a cell and searches through the first column of a table for that text. If it finds the text, it will delete that whole row but if it does not find that text then it shows a message box saying it was not found. I have been looking through other similar questions but none of them search for text found in a cell. My code I have right now looks like this.

Sub Remove1()  

Dim rng As Range 
Dim InputRng As Range 
Dim DeleteRng As Range 
Dim DeleteStr As String 

Set InputRng = Worksheets(1).Range("JobNumbers") 
DeleteStr = Worksheets(1).Range("Q8") 
For Each rng In InputRng     
    If rng.Value = DeleteStr Then        
        If DeleteRng Is Nothing Then             
            Set DeleteRng = rng         
        Else             
            Set DeleteRng = Application.Union(DeleteRng, rng)         
       End If     
    End If 
Next 
DeleteRng.EntireRow.delete  

End Sub 

When I try to run, it highlights the DeleteRng.EntireRow.delete row.

Answer 1

You want to check again if DeleteRng is Nothing before deleting rows:

If DeleteRng Is Nothing Then
    MsgBox "There's nothing to delete"
Else
    DeleteRng.EntireRow.delete
End If

If this won't help, you can try to add rows to DeleteRng :

If DeleteRng Is Nothing Then
    Set DeleteRng = rng.EntireRow
Else
    Set DeleteRng = Application.Union(DeleteRng, rng.EntireRow)
End If

And at the end:

DeleteRng.Delete

Answer 2

When you delete the row, you have to loop through in the reverse direction.

This example accepts the value to be searched, searches the value in Column A and deletes the entire row if found. If none of the value matches, then a message is shown.

Sub remove()
Dim i As Long, str As String, match As Boolean
str = InputBox("Enter the value to be searched")
match = False
For i = Cells(Rows.Count, 1).End(xlUp).Row To 1 Step -1
    If Cells(i, 1) = str Then
        Rows(i).Delete
        match = True
    End If
Next i
If match = False Then
    MsgBox "Value not found"
End If
End Sub

Alter this code as per your needs.

Answer 3

This is how I do what you are asking about.

The code below is set up in my test worksheets as follows:

On Sheet1 in column "A" I have a list of names entered down the column just to have some values to work with.

On Sheet2 in column "A" I have a Header in cell "A1" and then in a value typed into cell "A2" that I want to compare to each cell in Sheet1, column "A"

I placed a button on the worksheet. When the button is clicked the code runs. When a match is found then the entire row is deleted. I have a message box that tells me the number of rows deleted.

There are other ways to go about doing this. Maybe some of them are simpler than my technique. You should be able to adapt my code to fit your needs, though. I hope this helps.

Option Explicit

Sub Button2_Click()
    'Declare Variables
    Dim lastRow As Long
    Dim counter_1 As Long
    Dim counter_2 As Long
    Dim enteredValue As String
    Dim checkCellSheet_2 As String
    Dim checkRangeSheet_1 As String
    Dim answer As Long
    Dim matchCount As Integer
    Dim strMatchCount As String

    'Instantiate Variables
    checkCellSheet_2 = Sheet2.Cells(2, 1).Value
    enteredValue = checkCellSheet_2
    checkRangeSheet_1 = Sheet1.Range("A" & Rows.Count).End(xlUp).Value
    lastRow = Sheet1.Range("A1").CurrentRegion.Rows.Count
    matchCount = 0

    'Look in cell "A2" on Sheet 2 and delete
    'rows when a match is found in column "A"
    'On Sheet 1

    For counter_1 = lastRow To 1 Step -1
        Worksheets("Sheet1").Activate
        If checkCellSheet_2 = checkRangeSheet_1 Then
            For counter_2 = lastRow To 1 Step -1
                If Cells(counter_2, 1) = enteredValue Then
                    Rows(counter_2).Delete
                    matchCount = matchCount + 1
                End If
            Next
        ElseIf checkCellSheet_2 <> checkRangeSheet_1 Then
         'Do Nothing
        End If
        checkRangeSheet_1 = Sheet1.Range("A" & counter_1).Value
    Next counter_1

    strMatchCount = CStr(matchCount)
    answer = MsgBox("There were " + strMatchCount + " rows on Sheet 1, " _
                    + "with matching values in Column A of Sheet 1, deleted.")
End Sub