将所有文件从多个子文件夹移至父文件夹

Question

I found a nice script at https://superuser.com/questions/999922/move-all-files-from-multiple-subfolders-into-the-parent-folder

The main problem is I need a script which works for every subfolder and moves all files to the folder above from the Flacroot directory as initial point. For example Album1 --> Re-Encode, all content off Re-Encode should be moved to Album1 and that for every Album directory.

@echo off

FOR /R "C:\Source Folder" %%i IN (*.png) DO MOVE "%i" "C:\Staging Folder"

This script cannot do it for every subfolder. Has someone has an idea how that could be solved?

From:

|Flacroot
|    |Album1
|    |      |Re-Encode
|    |      |          |*.*
|Flacroot
|    |Album2
|    |      |Re-Encode
|    |      |          |*.*
|Flacroot
|    |Album3
|    |      |Re-Encode
|    |      |          |*.*

to:

|Flacroot
|    |Album1
|    |      |Re-Encode, *.*
|Flacroot
|    |Album2
|    |      |Re-Encode, *.*
|Flacroot
|    |Album3
|    |      |Re-Encode, *.*

Original and edited structure:

D:.
│   cuerenamer.bat
│
└───!Onmyōza
    │
    ├───Onmyo-Za - Welter of Hundred Demons
    │   │   Front.jpg
    │   │
    │   ├───Re-Encode
    │   │       01. Song1.flac
    │   │       02. Song2.flac
    │   │
    │   └───Scans
    │           02.jpg
    │           03.jpg
    │
    │───Onmyo-Za - Ninja Magic Story of Voluptuous Flower 
    │   │   Front.jpg
    │   │
    │   ├───Re-Encode
    │   │       01. Song1.flac
    │   │       02. Song2.flac
    │   │
    │   └───Scans
    │           02.jpg
    │           03.jpg
    │           04.jpg

Oh and important the Scans folder should be excluded and should not be touched. I hope this structure explains that good enough.

The script should run in the parent folder !Onmyōza and move the files as described.

Thank you!

Answer 1

This task is easy to achieve with the following batch code:

@echo off
for /D %%I in ("%~dp0*") do (
    if exist "%%I\Re-Encode\*" (
        move /Y "%%I\Re-Encode\*" "%%I\" 2>nul
        rd "%%I\Re-Encode" 2>nul
    )
)

%~dp0 references the drive and path of the batch file which is expanded to a directory path always ending with a backslash.

Command FOR with option /D searches for non-hidden directories matching the pattern * in directory of the batch file. This means FOR processes the directories Album1 , Album2 and Album3 with batch file being in directory Flacroot or Onmyo-Za - Welter of Hundred Demons and Onmyo-Za - Ninja Magic Story of Voluptuous Flower with batch file being in directory !Onmyōza .

The IF condition checks if there is in current subdirectory of the batch file's directory as found by FOR a subdirectory Re-Encode .

If there is a subdirectory Re-Encode , all files in this subdirectory are moved one directory level up to current subdirectory in batch file directory.

Then the subdirectory Re-Encode is removed which works only if it does not contain anymore any files or other subdirectories and not running process use this directory as current directory.

Error messages which could be output because of a file to move already exists in the album directory and being read-only, or the file to move is opened in an application resulting in a sharing access violation, or subdirectory Re-Encode is not empty on deletion, ... are suppressed by redirecting them from handle STDERR to device NUL .

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

• call /? ... explaining %~dp0
• echo /?
• for /?
• if /?
• move /?
• rd /?

Read also the Microsoft article about Using Command Redirection Operators for an explanation of 2>nul .