删除不包含字符串的行

Question

I am trying to search a table generated by another module and remove rows that do not contain the string "REPAIR_RTS" . I have tried several methods from this site but I get type mismatches every time I change the search value to "REPAIR_RTS" (the line that says CASE...).

Below is my latest attempt.

Public Sub Test()
lastRow = Range("D65000").End(xlUp).row
For i = lastRow To 2 Step -1
Select Case Cells(i, 4).Value
    Case "REPAIR_RTS"
        'Do nothing
    Case Else
        Cells(i, 8).EntireRow.Delete
End Select
Next i
End Sub

I am still new to VBA so I am having a very difficult time troubleshooting this. I am open to other methods as well, I am trying to learn new methods on the fly as I continue in my first analyst job.

Answer 1

The simplest way around this is to test for errors first...

err... no.

Simply change your Cells(i, 4).Value to Cells(i, 4).Text .

Still, .Text can be a pain as it returns exactly what is shown.

A bit less easy is the change from Cells(i, 4).Value to CStr(Cells(i, 4).Value) . However, it should do exactly what you want.

If you still have any Questions, just ask :D

Answer 2

You can't compare an error value (such as #N/A ) with a string - that is what is generating your "type mismatch" error.

The simplest way around this is to test for errors first, then continue testing for the specific string if it isn't an error:

Public Sub Test()
    Dim lastRow As Long
    Dim i As Long
    With Worksheets("Chargable Vendors")
        lastRow = .Cells(.Rows.Count, "D").End(xlUp).row
        For i = lastRow To 2 Step -1
            If IsError(.Cells(i, 4).Value) Then
                .Rows(i).Delete
            Else
                Select Case .Cells(i, 4).Value
                    Case "REPAIR_RTS"
                        'Do nothing
                    Case Else
                        .Rows(i).Delete
                End Select
            End If
        Next i
    End With
End Sub

---

An alternative would be to include, within the Select Case statement, the specific tests for each of the error values prior to testing for the string, eg

Select Case .Cells(i, 4).Value
    Case CVErr(xlErrNA), CVErr(xlErrDiv0), CVErr(xlErrName), CVErr(xlErrValue) 'etc
        .Rows(i).Delete
    Case "REPAIR_RTS"
        'Do nothing
    Case Else
        .Rows(i).Delete
End Select

but I find it easier to do the single IsError to test for all of them.

---

Note:

This could also be done with an If statement rather than a Select Case statement:

Public Sub Test()
    Dim lastRow As Long
    Dim i As Long
    With Worksheets("Chargable Vendors")
        lastRow = .Cells(.Rows.Count, "D").End(xlUp).row
        For i = lastRow To 2 Step -1
            If IsError(.Cells(i, 4).Value) Then
                .Rows(i).Delete
            ElseIf .Cells(i, 4).Value <> "REPAIR_RTS" Then
                .Rows(i).Delete
            End If
        Next i
    End With
End Sub