如何使用主要CMakeLists.txt中的cmake复制目标文件？

Question

As an example suppose four folders(app1, app2, app3 and main) such as below

main
|__ CMakeLists.txt
\__ module1
|______ CMakeLists.txt
|______ sub1.cpp
|______ sub1.h
\__ library5
|______ CMakeLists.txt
|______ sub5.cpp
|______ sub5.h
\__app1
\__app2
\__app3

Which output of module1 is module1.dll and output of library5 is lib5.dll. Folder of app1 must contain module1.dll and lib5.dll, app2 needs lib5.dll and finally app3 needs module1.dll(number of apps, modules and libs are more than this example and as I explain below we don't want to change modules/libraries's CMakeLists.txt , just main's CMakeLists.txt is ours).

PS:

I have a cmake project which has several libraries and modules. They included in my project using add_subdirectory command (note that my project just made up from multiple modules and it has not any add_library or add_target ).

I need to copy outputs of libraries/modules without changing their CMakeLists.txt ( add_custom_command with POST_BUILD option actually is not a good choice because at this point I need to change CMakeLists.txt of libraries/modules which they are not just belong to my project ). On the other hand it must done in outer(major) CMakeLists.txt which has others(libraries/modules).

I tried some other commands such as file (COPY ) and configure_file() but I think they operate in generating cmake-cache phase and just can copy resource files which are exist in pre-build phase.

Moreover, In another approach I write a bash script file to copy the files and call it in major CMakeLists.txt via bellow command.

add_custom_target (copy_all
        COMMAND ${CMAKE_SOURCE_DIR}/copy.sh ${files}
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
)

The files has the list of files. But the copy not performed! I manually test the script which works as desired. But I don't have any idea why it can not operate at call in CMakeLists.txt.

What can I do to copy sub-projects outputs to some locations from major CMakeLists.txt ?

Answer 1

The Setup

To simplify it a little, let's say you have:

CMakeLists.txt

cmake_minimum_required(VERSION 3.0)

project(PostBuildCopyFromRoot)

add_subdirectory(module)

module/CMakeLists.txt

file(WRITE "module.h" "int ModuleFunc();")
file(WRITE "module.cpp" "int ModuleFunc() { return 1; }")

add_library(module SHARED "module.cpp" "module.h")
target_include_directories(module PUBLIC "${CMAKE_CURRENT_SOURCE_DIR}")
set_target_properties(module PROPERTIES WINDOWS_EXPORT_ALL_SYMBOLS 1)

app/app.mexw64

The Problem

If you now just add to following to the root CMakeLists.txt :

add_custom_command(
    TARGET module
    POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy
        "$<TARGET_FILE:module>"
        "app/$<TARGET_FILE_NAME:module>"
)

You will get from CMake:

 CMake Warning (dev) at CMakeLists.txt:8 (add_custom_command): Policy CMP0040 is not set: The target in the TARGET signature of add_custom_command() must exist. Run "cmake --help-policy CMP0040" for policy details. Use the cmake_policy command to set the policy and suppress this warning. TARGET 'module' was not created in this directory. 

Solutions

You can always overwrite command behaviors:

    function(add_library _target)
        _add_library(${_target} ${ARGN})

        add_custom_command(
            TARGET ${_target}
            POST_BUILD
            COMMAND ${CMAKE_COMMAND} -E copy
                "$<TARGET_FILE:${_target}>"
                "${CMAKE_SOURCE_DIR}/app/$<TARGET_FILE_NAME:${_target}>"
        )
    endfunction()

NOTE: Put the code snippets before the add_subdirectory() call

References

• Copying executable and DLLs to User specified location using CMake in windows
• Parent CMakeLists.txt overwriting child CMakeLists.txt output directory options
• Proper usage of CMAKE_*_OUTPUT_DIRECTORY
• Is there a way to include and link external libraries throughout my project only editing my top level CMakeList?