Perl：多维哈希的取消引用数组

Question

My overall structure has three layers:

The first layer is a hash: Key :Continent Value : Country

The second layer is a hash: Key : Country Value : 2D array with specific countries

The Third layer is a 2D array

So far I have my code below:

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper qw(Dumper);

my %hash=(); #initialize a hash 
my $hash_ref = \%hash;

$hash{continent} = { 
    America => [
    ['North', 'Canada', 'USA'],
    ['South', 'Peru', 'Brazil'],
    ],
    Asia => [
    ['East', 'Japan', 'China'],
    ['Sounth', 'India','Bangladesh'],
    ],
}; 

foreach my $continent (keys %hash) {
    foreach my $country (keys %{ $hash{$continent} }) {
        print "$continent, $country : @{$hash{$continent}{$country}}\n";
    }
}

#print Dumper \%hash;

This is the output:

continent, Asia : ARRAY(0x7fb159824890) ARRAY(0x7fb15a004628)

continent, America : ARRAY(0x7fb159803ee8) ARRAY(0x7fb1598240e0)

My question is: How can I deference the 2D-array in the hash of the hash rather than get their reference??

Answer 1

If you have a choice, you should change your data structure's design to what @bipll suggested . Your existing data structure's design requires more complex code than necessary. If you can't, read on.

---

The first loop is incorrect.

This doesn't iterate over the continent names:

foreach my $continent (keys %hash) {

This does:

foreach my $continent (keys %{ $hash{continent} }) {

---

The second loop is incorrect.

$hash{$continent} now $hash{continent}{$continent} is a reference to an array, not a reference to a hash.

---

Fixed:

my $by_continent = $hash{continent};
for my $continent_name (keys(%$by_continent)) {
    my $continent = $by_continent->{$continent_name};
    for my $region (@$continent) {
        my $region_name = $region->[0];
        my @country_names = @{$region}[0..$#$region];
        print("$continent_name, $region_name: ", join(', ', @country_names), "\n");
    }
}

Answer 2

First of all, keys %hash is a singleton list ('continent') in your code. May I suppose you really wanted continent names as keys? Then simply write it as

my %hash = (America => [...], Asia => [...]);

Next, 'North' and 'South' look more like regions inside continents, you've probably missed a layer in design description.

Which suggests something like:

my %hash = (America => {North => ['Canada', 'USA'], South => ['Peru', 'Brazil']});
for my $continent (keys %hash) {
    for my $region (keys %{$hash{$continent}}) {
        print "$continent, $region, @{$hash{$continent}{$region}}\n"
    }
}

Output:

America, North, Canada USA
America, South, Peru Brazil