PHPExcel从x和y获取单元格

Question

I'm making a program and i'm using PHPExcel. Inside the program you can select width and height. (width is the green row, and blue is the height)

All the white numbers are prices. Lets say i insert 1400 width and 1600 height. the price should be 640. How can i achieve this?

Answer 1

The easiest option is to find which column contains 1400 in Row 1 ( D in your example), and which row contains 1600 in column A ( 5 in your example), and then use that to read the value at that cell ( D5 )

A somewhat cleverer way is to use an Excel Formula:

=INDIRECT(CONCATENATE(SUBSTITUTE(ADDRESS(1,MATCH(1400,A1:E1,0),4),1,""),MATCH(1600,A1:A17,0)))

substituting the appropriate lookup values for 1400 and 1600 , and adjusting the MATCH ranges to the full size for your width and height lookups.... In MS Excel itself, you could use row and column ranges ( A:A ) and ( 1:1 ), but the PHPExcel calculation engine won't handle row and column ranges correctly, but it will work with cell ranges

---

As an explanation for the above formula:

MATCH(1400,A1:E1,0)

Does a lookup for value 1400 in the cell range A1:E1 (looking for a match for your width). The returned value for MATCH() is a numeric offset in that row for the column where it is found. In this case, it will return 4 .

SUBSTITUTE(ADDRESS(1,<4>,4),1,"")

Converts the column number to a column letter... eg converts 4 to D . if your range didn't start at A , then you'd have to add an offset to get the correct letter

MATCH(1600,A1:A17,0)

Similar to the previous MATCH, but this time searching in your heights column range ( A1:A17 ) for the value 1600 . It will return the offset within that range where it finds the value. Again, if your range doesn't start in row 1 , then you'd need to add an offset. In your case, it will return 5 .

CONCATENATE(<D>,<5>)

Concatenates the calculated column and row values together to give a cell address ( D5 )

INDIRECT(<D5>)

Reads the value at the cell address that we've calculated ( D5 ) giving the value 640