VBA - 检查公式是否在单元格中运行缓慢

Question

Here is what I am looking at. I have a sheet that I import part of using the following VBA:

Sheets("Sheet1").Select
Range("D1:D1").Select
Selection.QueryTable.Refresh BackgroundQuery:=False

the issue with this is whenever I run it, it messes up the formulas I have in the A and B columns. So I created a sub that will check for that as follows:

Sub fixAnB()
    Dim sh As Sheet9
    Dim rw As Range
    Set sh = Sheet9
    sh.EnableCalculation = False
    'Sheets("Sheet1")
    Dim i As Long
    i = 0
    Dim f1 As String, f2 As String
    For Each rw In sh.Rows
        i = i + 1
        If i > 1 And sh.Cells(rw.Row, 4).Value <> "" Then
            f1 = "=CONCATENATE(G" & i & ",J" & i & ")"
            f2 = "=CONCATENATE(I" & i & ",H" & i & ",J" & i & ")"
            If sh.Cells(rw.Row, 1).Formula <> f1 Then sh.Cells(rw.Row,    1).Formula = f1
            If sh.Cells(rw.Row, 2).Formula <> f2 Then sh.Cells(rw.Row, 2).Formula = f2
        End If
        If sh.Cells(rw.Row, 4).Value = "" Then Exit For
    Next rw
    sh.EnableCalculation = True
End Sub

my issue with this is that I can have anywhere between 20,000 to 200,000 records on that sheet. so using the sub to fix the formulas takes about 10 - 15 mins. I am looking for one of solutions:

1. A way to fix the original problem so it doesn't mess up the references when I import my data

or 2. A way to make that fixer sub run way faster.

What do yall think?

Answer 1

Try this code (it takes less than 0.5s on my test on 200000 rows):

Sub Test()
 t = Timer
' Application.ScreenUpdating = False
' Application.EnableEvents = False
' Application.Calculation = xlCalculationManual

 Dim sh As Worksheet
 Set sh = ActiveSheet
 Dim i As Long
 i = sh.Range("D1").End(xlDown).Row
 sh.Range("A2:A" & i).Formula = "=CONCATENATE(G2,J2)"
 sh.Range("B2:B" & i).Formula = "=CONCATENATE(I2,H2,J2)"

' Application.ScreenUpdating = True
' Application.EnableEvents = True
' Application.Calculation = xlCalculationAutomatic
 MsgBox Timer - t
End Sub