如何使用表的前两列在Excel VBA中的用户窗体上创建两列组合框？

Question

I am looking to generate a combobox in a userform that pops up from clicking on a command button on my excel spreadsheet. The purpose is to select a date and time (including time in case there are multiple entries for a specific date) from the combobox then click an "Complete Action" command button on the form to change the value from "No" to "Yes" in a cell at the end of the row of the selected entry.

---

From the research that I have done so far, this was the only code I was able to comprehend enough to enter in, but I do not get the display results that I was hoping for.

Private Sub UserForm_Initialize()
Dim v, e
With Sheets("Phone Log").Range("B9:C76")
    v = .Value
End With

With CreateObject("scripting.dictionary")
    .comparemode = 1
    For Each e In v
        If Not .exists(e) Then .Add e, Nothing
    Next
    If .Count Then Me.combobox1.List = Application.Transpose(.keys)
End With


End Sub

---

Can someone please help with the code to display the dropdown list of the non-blank rows so that the two columns of reference data shows aligned and then take the selected row and change the cell value several columns to the right once the user clicks the "Complete Action" command button?

---

I would also be open to the combobox/user form being a separate sub so that I could use it as just selecting the row and running separate functions from command buttons that collect the user selected date.

TIA ~Decoy

Answer 1

I am not sure if this is what you need, but it should work (i tried it).

Tried to make it easy to read:

Option Explicit

Private Dic As New Scripting.dictionary 'needs a reference to "Microsoft scripting Runtime" in VBE>Tools>Reference

Private Sub CommandButton1_Click()
Dim h$
Dim i&
h = Me.ComboBox1.Value
If h = vbNullString Then Exit Sub
i = Dic(h) 'converts to a Long in this case
ThisWorkbook.Sheets("Phone Log").Cells(i, 3).Value2 = "YES" '3 is the "C" Column
End Sub

Private Sub UserForm_Initialize()
Dim v() 'needs to be a variant
Dim e$ 'is actually a string
Dim i& 'that's a Long

With ThisWorkbook.Sheets("Phone Log").Range("B1:B76") 'i only start at 1, because else i would need to be i-8 later on
    v = .Value 'do NOT use .value2 in case of dates, or currencys
End With

'Set Dic = CreateObject("scripting.dictionary")
With Dic
   ' .comparemode = 1 'didn't find help on this one, not needed i guess
    'For Each e In v
    For i = 9 To 76
       e = v(i, 1)
        If e <> vbNullString Then If Not .exists(e) Then Dic(e) = i '.Add e,i 'or ThisWorkbook.Sheets("Phone Log").cells(i,2).address
    Next i
    If .Count > 0 Then Me.ComboBox1.List = Application.Transpose(.keys) 'i learned something here
End With

Erase v
End Sub

Private Sub UserForm_Terminate()
Set Dic = Nothing
End Sub

EDIT : (sorry for the late answer, was beasy with my own stuff)

The previous code is for a one column combobox.

Here is an example on how to build a 3 column combobox (adjust code to your personal needs) :

With Me.Combobox1
    .ColumnCount = 3
    .ColumnWidths = "44;70;30"
    .ListWidth = 150
    .Clear
    .AddItem "*.XLSB"
    .List(0, 1) = "Binary"
    .List(0, 2) = "50"

    .AddItem "*.XLSM"
    .List(1, 1) = "Macro Enabled"
    .List(1, 2) = "52"

    .AddItem "*.XLS"
    .List(2, 1) = "Excel97"
    .List(2, 2) = "56"

    .ListIndex = 0
End With