如何在Prolog中递归计数和求和

Question

I'm trying to figure out how to use recursion on count and sum rules.

I usually do it with lists, using findall and length or findall and sum_list, but I'm not sure if that's my best option on all cases.

This is my approach with lists:

%person(name, surname, age)
person('A', 'H', 22).
person('B', 'G', 24).
person('C', 'F', 20).
person('D', 'E', 44).
person('E', 'D', 45).
person('F', 'C', 51).
person('G', 'B', 40).
person('H', 'A', 51).

count_person(Total_count) :-           % rule to count how many person are.
   findall(N, person(N, _, _), List),
   length(List, Total_count).

sum_ages(Total_sum) :-                 % rule to sum all the ages.

   findall(Age, person(_, _, Age), List),
   sum_list(List, Total_sum).

or here: https://swish.swi-prolog.org/p/cswl.pl

How should I do this using recursion?

Answer 1

I do not have an elegant solution. But with retract and assert you can control the recursion:

:- dynamic([person/3,person1/3]).

count_person(N) :-
    count_person(0,N).

count_person(Acc,N) :-
    retract(person(A,B,C)),
    !,
    assert(person1(A,B,C)),
    N1 is Acc+1,
    count_person(N1,N).
count_person(N,N) :-
    clean_db.

clean_db :-
    retract(person1(A,B,C)),
    assert(person(A,B,C)),
    fail.
clean_db.

Answer 2

You should take a look at library( aggregate ).

For instance:

count_person(Total_count) :-
  aggregate(count, A^B^C^person(A,B,C), Total_count).

or the simpler form (try to understand the difference, it's aa good way to learn the basic about variables quantification )

count_person(Total_count) :-
  aggregate_all(count, person(_,_,_), Total_count).

The library has grown out of the necessity to simplify the implementation of typical aggregation functions available in SQL (since Prolog is relational at heart):

sum_ages(Total_sum) :-
  aggregate(sum(Age), A^B^person(A,B,Age), Total_sum).

You can also get combined aggregates in a step. Average is readily implemented:

ave_ages(Ave) :- 
  aggregate(t(count,sum(Age)), A^B^person(A,B,Age), t(Count,Sum)), Ave is Sum/Count.

If you implement using count_person/1 and sum_ages/1 the interpreter would scan twice the goal...