在Delphi中将两个文本文件加载到一个TMemo组件中的最佳方法是什么？

Question

Let's say I have two text files (.txt) and I have a form with one TMemo Component on it. What would be the best way to quickly load both text files into the same Memo?

Answer 1

Use a TStringList to load each file and then use the AddStrings method to transfer the contents to the memo.

var
  Tmp: TStringList;
...
Memo1.Lines.BeginUpdate;
try
  Memo1.Lines.Clear;
  Tmp := TStringList.Create;
  try
    Tmp.LoadFromFile(FileName1);
    Memo1.Lines.AddStrings(Tmp);

    Tmp.LoadFromFile(FileName2);
    Memo1.Lines.AddStrings(Tmp);
  finally
    Tmp.Free;
  end;
finally
  Memo1.Lines.EndUpdate;
end;

In fact, this can easily be generalised to a potentially useful method like this:

procedure AppendMultipleTextFiles(Dest: TStrings; const FileNames: array of string);
var
  FileName: string;
  Tmp: TStringList;
begin
  Dest.BeginUpdate;
  try
    Tmp := TStringList.Create;
    try
      for FileName in FileNames do
      begin
        Tmp.LoadFromFile(FileName);
        Dest.AddStrings(Tmp);
      end;
    finally
      Tmp.Free;
    end;
  finally
    Dest.EndUpdate;
  end;
end;

You could then use the method like so:

Memo1.Lines.Clear;
AppendMultipleTextFiles(Memo1.Lines, [FileName1, FileName2]);

Answer 2

Something like this :

sl := TstringList.Create;
try
  sl.LoadFromFile('1.TXT');
  memo1.Lines.Add(sl.Text);

  sl.Clear;
  sl.LoadFromFile('2.TXT');
  memo1.Lines.Add(s2.Text);


finally
  sl.Free
end;

Answer 3

Without any TStringList:

uses System.IOUtils;

Memo1.Text := TFile.ReadAllText('1.txt') + #13#10 + TFile.ReadAllText('2.txt');

When you assign string with line breaks to TStrings.Text, this string will be automatically splitted into multiple strings, what can be proven with a following console program:

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils,
  System.Classes,
  System.IOUtils;

var StringList: TStringList;
    s: string;
begin
  try
    StringList := TStringList.Create;
    StringList.Text := TFile.ReadAllText('1.txt');
    for s in StringList do
      begin
        Writeln(s);
        Writeln('-----');
      end;
    Readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

More from docwiki

When setting Text, the value will be parsed by separating into substrings whenever a carriage return or linefeed is encountered. (The two do not need to form pairs).

This method improves readability, but consumes big amount of memory.