ORACLE 更新并返回 OLD 和 NEW 值

Question

Is there equivalent to this T-SQL query in PL/SQL (Oracle 12c)?

UPDATE A SET A.columnA = 10 WHERE A.columnB < 30 OUTPUT INSERTED.*, DELETED.*

The query updates table A and at the same time returns the status of the record before the update and after the update.

Trigger is not a solution for me as well as SELECT records before and SELECT records after updating.

Answer 1

Not a direct one, but using RETURNING INTO you will be able to achieve the same effect:

CREATE TABLE A(columnA VARCHAR2(10), columnB INT);
INSERT INTO A(columnA, columnB) VALUES ('Test', 10);
INSERT INTO A(columnA, columnB) VALUES ('Row 2', 20);
CREATE TABLE audit_table(col_new VARCHAR2(10),col_old VARCHAR2(10));

DECLARE
   TYPE rec IS RECORD (actual A.columnA%TYPE, old A.columnA%TYPE);
   TYPE col_a_t IS TABLE OF rec;
   v_a col_a_t;
BEGIN
  UPDATE (SELECT A.*, (SELECT A.columnA FROM dual) AS old_columnA FROM A)
  SET columnA = 'XYZ'
  WHERE columnB < 30
  RETURNING columnA, old_columnA BULK COLLECT INTO v_a;
  COMMIT;

  -- printing for debug
  FOR i IN v_a.first .. v_a.last LOOP
     dbms_output.put_line('Old =>' || v_a(i).old || ' new => ' || v_a(i).actual);
  END LOOP;

  -- additional
  FORALL i IN v_a.first .. v_a.last
    INSERT INTO audit_table VALUES v_a(i);
  COMMIT;
END;
/

SELECT * FROM A;
SELECT * FROM audit_table;

DBFiddle Demo

---

^{Idea taken from: Returning Old value during update}

Answer 2

How would be above code look like in case when using execute immediate? Something like this? I have skipped the insert part for simplicity.

DECLARE
    sql_update  VARCHAR2(4000) := NULL;
    TYPE rec IS RECORD (
        actual  a.columna%TYPE,
        old     a.columna%TYPE
    );
    TYPE col_a_t IS
        TABLE OF rec;
    v_a         col_a_t;
BEGIN
    sql_update := 'UPDATE (SELECT A.*, (SELECT A.columnA FROM dual) AS old_columnA FROM A)'
                  || 'SET columnA = ''XYZ'''
                  || 'WHERE columnB < 30'
                  || 'RETURNING columnA, old_columnA BULK COLLECT INTO v_a';
 -- COMMIT;
    EXECUTE IMMEDIATE sql_update;
  -- printing for debug
    FOR i IN v_a.first..v_a.last LOOP
        dbms_output.put_line('Old =>'
                             || v_a(i).old
                             || ' new => '
                             || v_a(i).actual);
    END LOOP;
END;
/

When I execute above code I get

ORA-00925: missing INTO keyword

Answer 3

you mean like this? but I get still the same error:

DECLARE
    sql_update  VARCHAR2(4000) := NULL;
    TYPE rec IS RECORD (
        actual  a.columna%TYPE,
        old     a.columna%TYPE
    );
    TYPE col_a_t IS
        TABLE OF rec;
    v_a         col_a_t;
BEGIN
    sql_update := ' UPDATE (SELECT A.*, (SELECT A.columnA FROM dual) AS old_columnA FROM A) '
                  || ' SET columnA = ''XYZ'' '
                  || ' WHERE columnB < 30 '
                  || ' RETURNING columnA, old_columnA BULK COLLECT INTO v_a ';
 -- COMMIT;
    EXECUTE IMMEDIATE sql_update;
  -- printing for debug
    FOR i IN v_a.first..v_a.last LOOP
        dbms_output.put_line('Old =>'
                             || v_a(i).old
                             || ' new => '
                             || v_a(i).actual);
    END LOOP;
END;
/