如何使用Excel VBA和userform编辑嵌入在Excel中的PowerPoint演示文稿

Question

I am building a database with information on a large collection of product designs. I chose to use an Excel file with userform input for the design details so as to easily filter by detail, then select a link to the corresponding page that contains an embedded PowerPoint with photos and design notes. At the moment I have a template that copies into a new tab, renames and creates a link to the tab in a directory based on text box input of part number. I might be asking too much but I'd also like the userform to add text to preexisting text boxes within the PowerPoint presentation. Everything up to this point works rather well.

I found a similar question and tried my hand at coding several times.

Editing Embedded PowerPoint from Excel VBA

It was helpful in understanding but it didn't work for me in this context:

Private Sub cmdAddSlide_Click()

    template = "Slide Template"

    'Hide the sheet
    ufrmAddSlide.Hide

    'Copy the template to create a new sheet.
    Sheets(template).Select
    Sheets(template).Copy After:=Sheets(Sheets.Count)

    'Make the sheet visible in case the template is hidden.
    ActiveSheet.Visible = xlSheetVisible

    'Rename the sheet.
    ActiveSheet.Name = txtPartNumber

    'Add data to powerpoint object.
    Worksheets(Me.txtPartNumber.Value).Shapes("Object 1").Select 
    Selection.Verb Verb:=xlOpen
    Dim p As PowerPoint.Presentation
    Set p = Selection.Object
    ActivePresentation.Slides(1).Shapes("operationaltext1").TextFrame.TextRange.Text = Me.txtPartNumber.Value
    [a1].Select

    'Bring main sheet back to front if necessary.
    If chkBringToFront = False Then
        Sheets("Directory").Select
    End If

    'Copy input values to sheet.
    Dim lRow As Long
    Dim ws As Worksheet
    Set ws = Worksheets("Directory")
    lRow = ws.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).Row

    With ws    
        'Create a link to the part design page with the part number text.
        ActiveSheet.Hyperlinks.Add Anchor:=.Cells(lRow, 1), Address:="", 
        SubAddress:=Me.txtPartNumber.Value & "!A1", 
        TextToDisplay:=Me.txtPartNumber.Value
        .Cells(lRow, 1).Value = Me.txtPartNumber.Value
        .Cells(lRow, 2).Value = Me.txtCustomer.Value
        .Cells(lRow, 3).Value = Me.cboSkydrol.Value
        .Cells(lRow, 4).Value = Me.cboPneumatic.Value
        .Cells(lRow, 5).Value = Me.cboFuel.Value
        .Cells(lRow, 6).Value = Me.cboRedOil.Value
        .Cells(lRow, 7).Value = Me.cboSpace.Value
        .Cells(lRow, 8).Value = Me.cboStyle.Value
        .Cells(lRow, 9).Value = Me.txtWeight.Value
        .Cells(lRow, 10).Value = Me.txtMaxPressure.Value
        .Cells(lRow, 11).Value = Me.txtOperatingPressure.Value
        .Cells(lRow, 12).Value = Me.txtProofPressure.Value
        .Cells(lRow, 13).Value = Me.txtBurstPressure.Value
        .Cells(lRow, 14).Value = Me.txtAmbientTemperature.Value
        .Cells(lRow, 15).Value = Me.txtFluidTemperature.Value
        .Cells(lRow, 16).Value = Me.txtPullIn.Value
        .Cells(lRow, 17).Value = Me.txtDropOut.Value
        .Cells(lRow, 18).Value = Me.txtCoilResistance.Value
        .Cells(lRow, 19).Value = Me.txtLeakage.Value
        .Cells(lRow, 20).Value = Me.txtFlow.Value
        .Cells(lRow, 21).Value = Me.txtNotes.Value
    End With

    'Clear all inputs.
    Me.cboSkydrol.Value = ""
    Me.cboPneumatic.Value = ""
    Me.cboFuel.Value = ""
    Me.cboRedOil.Value = ""
    Me.cboSpace.Value = ""
    Me.cboStyle.Value = ""
    Me.txtAmbientTemperature.Value = ""
    Me.txtBurstPressure.Value = ""
    Me.txtCoilResistance.Value = ""
    Me.txtDropOut.Value = ""
    Me.txtFlow.Value = ""
    Me.txtFluidTemperature.Value = ""
    Me.txtLeakage.Value = ""
    Me.txtMaxPressure.Value = ""
    Me.txtNotes.Value = ""
    Me.txtOperatingPressure.Value = ""
    Me.txtPartNumber.Value = ""
    Me.txtProofPressure.Value = ""
    Me.txtPullIn.Value = ""
    Me.txtWeight.Value = ""
    Me.txtCustomer.Value = ""
End Sub

The PowerPoint Presentation opened in a separate window but nothing was changed. Also, the rest of my VBA code didn't execute. Though I'm only a week into my understanding of ExcelVBA coding. So far has been just trying Frankenstein code from several sites.

Can I do this without opening the slide in a separate window?

I'd appreciate some input. :)

The workbook contains worksheets "Slide Template" and "Directory".

The PowerPoint slide is named "Object 1".

The destination texbox within the slide is named "operationaltext1".

Answer 1

here is some code that inserts a powerpoint slide, adds text to it and also reads the text back

if you only need one slide, then this is for you

Option Explicit

Sub testPPslide()

    ' NOTE: this adds a slide everytime the code is run
    ' it will be the standard "click here to add title" slide

    Worksheets("Sheet1").Range("c1:d1") = ""

    Dim pps As OLEObject

    Set pps = Worksheets("Sheet1").OLEObjects.Add( _
            ClassType:="PowerPoint.Slide.12", _
            Link:=False, _
            DisplayAsIcon:=False)

'   pps.Verb Verb:=xlOpen                     ' this edits slide in standalone PP app
'   pps.Verb Verb:=xlPrimary                  ' this one opens PP in excel
    pps.Top = 40
    pps.Left = 60

    Dim ps As powerpoint.Slide
    Set ps = pps.Object

    ps.Shapes(1).TextFrame.TextRange.Text = "cccccccccc"
    ps.Shapes(2).TextFrame.TextRange.Text = "this works"

    Worksheets("Sheet1").Range("c1") = ps.Shapes(1).TextFrame.TextRange.Text
    Worksheets("Sheet1").Range("d1") = ps.Shapes(2).TextFrame.TextRange.Text

End Sub

Answer 2

this one works on presentations

example code

Option Explicit


Sub testPPpresentation()

    ' NOTE: adds a PP presentation to the worksheet each time it is run

    Worksheets("Sheet1").Range("c1:d1") = ""

    Dim aaa As OLEObject
    Set aaa = Worksheets("Sheet1").OLEObjects.Add( _
                ClassType:="PowerPoint.Show.12", _
                Link:=False, _
                DisplayAsIcon:=False)

'   aaa.Verb Verb:=xlOpen       ' this edits the presentation in standalone PP app
'   aaa.Verb Verb:=xlPrimary    ' this one edits the presentation in excel

    aaa.Top = 90
    aaa.Left = 60

    Dim ppp As PowerPoint.Presentation
    Set ppp = aaa.Object

    ppp.Slides(1).Shapes(1).TextFrame.TextRange.Text = "cccccccccc"
    ppp.Slides(1).Shapes(2).TextFrame.TextRange.Text = "this works"

    Worksheets("Sheet1").Range("c1") = ppp.Slides(1).Shapes(1).TextFrame.TextRange.Text
    Worksheets("Sheet1").Range("d1") = ppp.Slides(1).Shapes(2).TextFrame.TextRange.Text

End Sub