groovy 从文件中读取数据

Question

I need some help with reading data from txt file. I want to indicate if line is inside 'project' section. And if so look for com.google.maps.api:1.9.10 . I should get information whether it is in project section. I don't provide here any source code, because I don't have an idea how to think about this situation. Maybe you have any idea how to resolve this.

Sample input:

Below example data from file:

+--- project :google-json
|    +--- other data
|    +--- other data
|    +--- com.google.maps.api:1.9.10
|    +--- other data
+--- something :google-json
|    +--- other data
|    +--- other data
|    +--- com.google.maps.api:2.2.2
|    +--- other data

Answer 1

First idea here is to loop over the lines splitted with new line character ( \\n ) then check if you're in appropriate section and then verify if any subsequent line contains the wanted value. If so it's found, otherwise it's not.

The second idea is to use more data oriented approach. Use the regex to split data into sections, then transform them to tuples and look for a tuple with appropriate name which will have the wanted value in it's value. Here's how it goes:

def input = '''
+--- project :google-json
|    +--- other data
|    +--- other data
|    +--- com.google.maps.api:1.9.10
|    +--- other data
+--- something :google-json
|    +--- other data
|    +--- other data
|    +--- com.google.maps.api:2.2.2
|    +--- other data
'''
input
    .split(/(?ms)(^\+--- )/)
    .toList()
    .findAll { !it.trim().isEmpty() }
    .collect {
        def section = it.substring(0,it.indexOf('\n'))
        new Tuple(
            section,
            (it - section)
            .trim()
            .split('\n')
            .collect { (it - '|    +---').trim() }
        )
    }
   .find {
       it.get(0) == 'project :google-json' && it.get(1).find { 'com.google.maps.api:1.9.10'.equals(it) }
   }

1. Split lines with appropriate regex - here, a line with that starts with +--- is a delimiter.
2. Since split returns array, turn it int list.
3. Remove all empty elements.
4. Transform data into tuples. The first value is section name (eg project :google-json ), the second is a list of dependencies with ASCII art tree elements removed.
5. Find the wanted tuple.