PLS-00103：在FlyWay中遇到符号“文件结尾”

Question

We have a database migration scripts, which are run trough FlyWay, which is part of Java app. The problem is that some customers have the older version of app, where some table and data are presented, while others will be installing this product as new solution. These scripts must run everytime (solution problem and historical problem).

In fact, we handle this in SQL with simple check, if table exist and then execute the rest of script. It works quite fine for other databases (Postgres, MySQL, MS SQL) but not for Oracle. And after few days of trying and googling I am starting to rip my hair off of my head. First problem was executing DDL statements (already learned I can't do that) and now this.

What are we traing to achieve:

1. Run script if main table exists for current user (that's how we determine, if all other table exists too)
2. For every table we need to create a backup table and copy all rows in it (thats why we do TRUNCATE and INSERT INTO and if fails, we do CREATE TABLE AS) - this is what presented code should do, block of code inside IF table_count > 0 THEN and END IF; is repeated per every table presented (11x)
3. We then run the cleanup script, which checks for bad data and clean them (we must have original values stored in case something goes bad).
4. Cleaned datas are copied into new tables (prepared in previous script).

There is 10 scripts in total, but this one is constantly failing.

Here is the code:

DECLARE 
  table_count NUMBER;
  curr_user VARCHAR2(100);  
BEGIN
  SELECT
  sys_context('USERENV','SESSION_USER') INTO curr_user 
  FROM dual;

  SELECT count(*)
  INTO table_count
  FROM all_objects
  WHERE object_type IN ('TABLE', 'VIEW')
  AND object_name = 'main_table'
  AND owner = curr_user;

  IF table_count > 0 THEN
    BEGIN
      EXECUTE IMMEDIATE 'TRUNCATE TABLE some_table_backup';
      EXECUTE IMMEDIATE 'INSERT INTO some_table_backup
          SELECT *
          FROM some_table';
      EXCEPTION
      WHEN OTHERS THEN
      IF SQLCODE != -942
      THEN
        RAISE;
      ELSE
        EXECUTE IMMEDIATE 'CREATE TABLE some_table_backup AS SELECT * FROM some_table';
      END IF;
    END;

    BEGIN
      EXECUTE IMMEDIATE 'TRUNCATE TABLE some_table_backup2';
      EXECUTE IMMEDIATE 'INSERT INTO some_table_backup2
          SELECT *
          FROM some_table2';
      EXCEPTION
      WHEN OTHERS THEN
      IF SQLCODE != -942
      THEN
        RAISE;
      ELSE
        EXECUTE IMMEDIATE 'CREATE TABLE some_table_backup2 AS SELECT * FROM some_table2';
      END IF;
    END;   
.
.
.

  END IF;

EXCEPTION
  WHEN OTHERS
  THEN
  DBMS_OUTPUT.put_line(SQLERRM);
END;

The error is following:

ORA-06550: line 30, column 8:

PLS-00103: Encountered the symbol "end-of-file" when expecting one of the following:

Line 30 is END; after END IF; in first partition of script.

Answer 1

It looks like that your version of FlyWay does not like nested PL/SQL Blocks. I would try to add anonymous block labels:

DECLARE 
  table_count NUMBER;
  curr_user VARCHAR2(100);  
BEGIN
  SELECT
  sys_context('USERENV','SESSION_USER') INTO curr_user 
  FROM dual;

  SELECT count(*)
  INTO table_count
  FROM all_objects
  WHERE object_type IN ('TABLE', 'VIEW')
  AND object_name = UPPER('main_table')    --here I added UPPER
  AND owner = curr_user;

  IF table_count > 0 THEN
    <<name1>>
    BEGIN
      EXECUTE IMMEDIATE 'TRUNCATE TABLE some_table_backup';
      EXECUTE IMMEDIATE 'INSERT INTO some_table_backup
          SELECT *
          FROM some_table';
      EXCEPTION
      WHEN OTHERS THEN
      IF SQLCODE != -942
      THEN
        RAISE;
      ELSE
        EXECUTE IMMEDIATE 'CREATE TABLE some_table_backup AS SELECT * FROM some_table';
      END IF;
    END name1;

    <<name2>>
    BEGIN
      EXECUTE IMMEDIATE 'TRUNCATE TABLE some_table_backup2';
      EXECUTE IMMEDIATE 'INSERT INTO some_table_backup2
          SELECT *
          FROM some_table2';
      EXCEPTION
      WHEN OTHERS THEN
      IF SQLCODE != -942
      THEN
        RAISE;
      ELSE
        EXECUTE IMMEDIATE 'CREATE TABLE some_table_backup2 AS SELECT * FROM some_table2';
      END IF;
    END name2;   


  END IF;

EXCEPTION
  WHEN OTHERS
  THEN
  DBMS_OUTPUT.put_line(SQLERRM);
END;
/

---

Alternatively you could avoid nested PL/SQL block by changing approach.

Instead of trying to do something first and handle exception, you could easily check if table exist or not and then do the action. That way there is no need for nested PL/SQL blocks at all.

Second alternative is to use dynamic SQL:

DECLARE 
  table_count NUMBER;
  curr_user VARCHAR2(100);  
BEGIN
  SELECT
  sys_context('USERENV','SESSION_USER') INTO curr_user 
  FROM dual;

  SELECT count(*)
  INTO table_count
  FROM all_objects
  WHERE object_type IN ('TABLE', 'VIEW')
  AND object_name = UPPER('main_table')
  AND owner = curr_user;

  IF table_count > 0 THEN

    EXECUTE IMMEDIATE q'{
    BEGIN
      EXECUTE IMMEDIATE 'TRUNCATE TABLE some_table_backup';
      EXECUTE IMMEDIATE 'INSERT INTO some_table_backup
          SELECT *
          FROM some_table';
      EXCEPTION
      WHEN OTHERS THEN
      IF SQLCODE != -942
      THEN
        RAISE;
      ELSE
        EXECUTE IMMEDIATE 'CREATE TABLE some_table_backup AS SELECT * FROM some_table';
      END IF;
    END;}';

    EXECUTE IMMEDIATE q'{
    BEGIN
      EXECUTE IMMEDIATE 'TRUNCATE TABLE some_table_backup2';
      EXECUTE IMMEDIATE 'INSERT INTO some_table_backup2
          SELECT *
          FROM some_table2';
      EXCEPTION
      WHEN OTHERS THEN
      IF SQLCODE != -942
      THEN
        RAISE;
      ELSE
        EXECUTE IMMEDIATE 'CREATE TABLE some_table_backup2 AS SELECT * FROM some_table2';
      END IF;
    END;}';   

  END IF;

EXCEPTION
  WHEN OTHERS
  THEN
  DBMS_OUTPUT.put_line(SQLERRM);
END;

Please note the usage of q'{}' text literal that allow to handle ' without duplicating them.

With FlyWay 4.2.0(called from command-line) both samples work as it should.