Excel VBA排除词

Question

I have some exclusion words namely: Limited, Corporation, Incorporation, Inc, Ltd and Co in cells A2 to A6 respectively.

In column B, it will be the input value of namely: ABC Limited, XYZ Holdings Corporation Limited and Tesco Bee Co Ltd in cells B2 to B4 respectively.

In column C, it will display the results of B with the exclusion of any or all words from column A. It should show results of ABC, XYZ Holdings and Tesco Bee respectively.

Will there be any formula or macros that will be able to solve this issue?

I have attached a link to sample of what I am trying to illustrate.

I have tried this code:

Sub test()
    Dim OriginalText As String
    Dim CorrectedText As String 
    OriginalText = Range("C4").Value 
    CorrectedText = Replace(OriginalText, "Limited", "") 
    Range("C4").Offset(, 1).Value = CorrectedText 
End Sub

However, I do not know how to incorporate all exclusion words in it, currently I managed to exclude "Limited" only.

Answer 1

Taking your code and putting it into a loop:

Sub test()
    Dim Exclusions As Variant
    Dim CorrectedText As String 
    Dim r As Long
    Dim i As Long
    'Get all the "exclusions" from column A
    Exclusions = Range("A2", Range("A" & Rows.Count).End(xlUp)).Value
    'Loop through all the cells in column C
    For r = 2 To Cells(Rows.Count, "C").End(xlUp).Row
        'Start with the current value
        CorrectedText = Cells(r, "C").Value 
        'Remove, one word at a time, any words that are excluded
        For i = LBound(Exclusions, 1) To UBound(Exclusions, 1)
            CorrectedText = Replace(CorrectedText, Exclusions(i, 1), "") 
        Next
        'Put whatever is left in column D
        Cells(r, "D").Value = CorrectedText 
    Next
End Sub