根据单元格颜色更改Excel中单元格的值

Question

I am using the following VBA code to change the value of cells based on their color but it changes all selected cells including colored cells. Please help me in this regard:-

Sub ChangeValueBasedOnCellColor()
    Dim rg As Range
    Dim xRg As Range
    Set xRg = Selection.Cells
    Application.DisplayAlerts = False
    For Each rg In xRg
        With rg
            Select Case .Interior.Color
                Case Is = 16777215
                    .Value = "OFF"

            End Select
        End With
    Next
    Application.DisplayAlerts = False
End Sub

Answer 1

The issue you are having is that both a cell with no/unset/default ^* background colour and a cell with a background colour explicitly set to white have the same .Interior.Color property value ( 16777215 ).

To distinguish the two, you need to check each cell's .Interior.ColorIndex property instead. A cell with no background colour has .Interior.ColorIndex equal to xlNone ( -4142 ) whilst a cell with a set white background colour has .Interior.ColorIndex equal to 2 .

Thus, your code needs to be changed to the following to correctly set the value of the "white" coloured cells to OFF :

Sub ChangeValueBasedOnCellColor()
  Dim rg As Range
  Dim xRg As Range
  Set xRg = Selection.Cells
  Application.DisplayAlerts = False
  For Each rg In xRg
    With rg
      Select Case .Interior.ColorIndex
        Case Is = 2
          .Value = "OFF"
      End Select
    End With
  Next
  Application.DisplayAlerts = False
End Sub

Note:
^* If your default background colour is not white, the .Interior.Color property value is still white. This is because the only way to "change" the default cell colour is by adding a coloured background image. The underlying cell's background colour remains unset.