NSIS运行时未创建按钮

Question

I try to create Windows installer with radiobuttons page where the buttons are created runtime from found files path. But only first file path is used for radiobutton creating only. When I uncomment MessageBox line the all files path are shown. Could anybody help me please?

Thanks

Function getButtons
  nsDialogs::Create 1018
  Pop $dialog
  ${NSD_CreateGroupBox} 0 0 100% 100% "These DLLs were found installed"
  # get available plugins
  ${locate::Open} "$dllDir" `/F=1 /D=0 /M=*.dll /B=1` $0
  StrCmp $0 0 0 loop
  MessageBox MB_OK "Error! No DLL files found..., $dllDir" IDOK close

  loop:
  # counter for y value
  StrCpy $R1 10
  # find possible plugins for installation
  ${Do}
    ${locate::Find} $0 $1 $2 $3 $4 $5 $6
    ${If} $1 == ""
      ${ExitDo}
    ${EndIf}
    ;MessageBox MB_OK "Path=$1" IDOK
    # calculate radiobutton y value
    IntOp $R1 $R1 + 20
    ${NSD_CreateRadioButton} 20 $R1 100% 50% "$1"
    Pop $hwnd
    nsDialogs::SetUserData $hwnd "$1"
    ${NSD_OnClick} $hwnd RadioClick
  ${Loop}
  close:
  ${locate::Close} $0
  ${locate::Unload}
  nsDialogs::Show
FunctionEnd

Answer 1

The controls are all there, they are just not visible because you have set the height to 50% and the radio controls are not transparent.

You could make them transparent:

${NSD_CreateRadioButton} 20 $R1 100% 50% "$1"
Pop $hwnd
SetCtlColors $hwnd SYSCLR:8 Transparent ; NSIS 3.1+
${NSD_AddExStyle} $hwnd ${WS_EX_TRANSPARENT} ; https://blogs.msdn.microsoft.com/oldnewthing/20121217-00/?p=5823

but the NSIS documentation warns against this:

Warning: Setting the background color of check boxes to transparent may not function properly when using XPStyle on . The background may be completely black instead of transparent when using certain Windows themes.

It is better to just size your controls correctly in the first place:

!include nsDialogs.nsh

Page Custom getButtons
Page InstFiles

var hwnd

Function getButtons
nsDialogs::Create 1018
Pop $0

${NSD_CreateGroupBox} 0 0 100% 100% "These DLLs were found installed"
Pop $0

StrCpy $R1 0 ; Measured in dialog units, not pixels
FindFirst $0 $1 "$sysdir\sh*.dll"
loop:
    StrCmp $1 "" end
    IntOp $R1 $R1 + 12
    ${NSD_CreateRadioButton} 5u $R1u -20 12u "$1"
    Pop $hwnd
    nsDialogs::SetUserData $hwnd "$1"
    ${NSD_OnClick} $hwnd RadioClick
    FindNext $0 $1
    Goto loop
end:
FindClose $0

nsDialogs::Show
FunctionEnd

If you don't know how many files there are then it is better to use a listbox so you don't run out of space in the dialog.