如何在J中编写最大化或最小化函数

Question

例如，如果我想使收益函数E [r] = w1r1 + w2r2的期望最大化，并求解权重w1和w2的优化值。

Answer 1

The only constraint that you have really given is that w1+w2=1

   w1 =.0.25
   (,~ -.)w1
0.25 0.75

That takes care of both w1 and w2 given the value of w1.

r1 r2 +/@:* w1 w2 calculates r1w1 + r2w2

   r1 =. 5
   r2 =.10
   (r1,r2) (+/@:* (,-.))w1
8.75
   (r1,r2) (+/@:* (,-.))0.9
5.5
   (r1,r2) (+/@:* (,-.))0.01
9.95

If you really wanted to maximize you would need to add equations for the value of r1 and r2 and take those into account as well, but perhaps I don't understand your question?

Responding to the comment below: If the constraint of w1+w2=1 still is in play, then the matter just becomes summing the values in r1 and r2, then whichever is bigger should get the w value of 1 and the other will get the w value of 0

   r1=.2 4 6 3 2
   r2=.2.1 4 6 3 2
   r3=.2 4 6 3 2.3
   r1 (,-.)@:>/@:(+/@:,.) r2
0 1
   r2 (,-.)@:>/@:(+/@:,.) r1
1 0
   r3 (,-.)@:>/@:(+/@:,.) r2
1 0
   'w1 w2'=.r3 (,-.)@:>/@:(+/@:,.) r2
   w1
1
   w2
0
   'w1 w2'=.r1 (,-.)@:>/@:(+/@:,.) r2
   w1
0
   w2
1
   (r1,.r2) +/@:,@:(+ . *) (0 1) NB. w1=.0 w2=.1
17.1
   (r1,.r2) +/@:,@:(+ . *) (1 0) NB. w1=.1 w2=.0
17
   (r1,.r2) +/@:,@:(+ . *) (0.5 0.5) NB. w1=.0.5 w2=.0.5
17.05

Based on the follow up comment below I would approach it in one of two ways. I could dig up all my linear programming texts from the 1980's and come up with the definitive mathematical solution (including degenerative cases and local maxima/ minima) or using the same technique as above but for a larger case than n=2. I'm going with the second option.

Let's look first at the r matrix which will be a set of constants. For this example I am taking a random 5 X 10 matrix with values from 1 to 10.

   r=. >: ? 5 10 $ 10
   r
 4 4 8  1  4 3 6  9  6 2
 2 6 5  4  4 7 5 10  4 6
 2 4 9 10  1 1 9  8  2 7
 5 6 5  4  7 9 2  6 10 6
10 3 6  2 10 2 7 10  4 2

Now the trick that I am going to use is that I want to find the column with the highest average to be multiplied by the largest value of w. Easy to do with J using (+/ % #)

   (+/ % #) r
4.6 4.6 6.6 4.2 5.2 4.4 5.8 8.6 5.2 4.6

Then find the ranking of the list to be able to reorder the columns of the original r matrix. The leading 7 means that 7 { r is the largest average etc.

   \:@:(+/ % #) r
7 2 6 4 8 0 1 9 5 3

I use this to in turn reorder the columns of the matrix r using {"1 since I am working columns. The result is that I have reordered the columns of r so that the column with the largest average is on the left and smallest on the right.

   (\:@:(+/ % #) {"1 ]) r
 9 8 6  4  6  4 4 2 3  1
10 5 5  4  4  2 6 6 7  4
 8 9 9  1  2  2 4 7 1 10
 6 5 2  7 10  5 6 6 9  4
10 6 7 10  4 10 3 2 2  2

Once I have that, then the next thing is to develop the w vector. Since I now have all the largest averages on the left I will just maximize the values to the left of w to be as large as possible within the noted constraints.

   w=. 0.2 0.2 0.2 0.2 0.15 0.01 0.01 0.01 0.01 0.01
   #w  NB. w1 through w10 
10
   +/w NB. sum of the values in w
1
   >./w NB. largest value in w
0.2
   <./w NB. smallest value in w
0.01

Because the r matrix has been reordered using + . * + . * the dot product gives values for w1r1 , w2r2 , w3r3 ... w10r10

   (({"1~ \:@: (+/ % #))r) + . * w
1.8 1.6 1.2 0.8 0.9 0.04 0.04 0.02 0.03 0.01
  2   1   1 0.8 0.6 0.02 0.06 0.06 0.07 0.04
1.6 1.8 1.8 0.2 0.3 0.02 0.04 0.07 0.01  0.1
1.2   1 0.4 1.4 1.5 0.05 0.06 0.06 0.09 0.04
  2 1.2 1.4   2 0.6  0.1 0.03 0.02 0.02 0.02

to actually get the weight of the matrix ravel all the values then sum

   +/ , (({"1~ \:@: (+/ % #))r) + . * w
31.22