使用存储过程和命令时，VBA RecordSet.RecordCount = -1

Question

I call a stored procedure with a command. I receive the result in a record set. Now I need to do some calculations and therefore need to know number of records that was returned. RecordSet.RecordCount should give me that but only returns -1. I have tried different values of CursorType and CursorLocation, tried MoveLast. Nothing helps.

I made a temporary solution by assuming a fixed number for the number of records.

There are many threads here about RecordCount, and also articles, that I read but nothing seems to help. Is the problem that I use a command? Most examples I see dont use commands.

I am an experienced programmer but not so used to SQL and VBA. Anyone who can give me some help?

Best Regards, Wolfgang

Sub CallStoredProcedure()

Dim Conn As ADODB.Connection, RecordSet As ADODB.RecordSet

Dim Command As ADODB.Command
Dim ConnectionString As String, StoredProcName As String
Dim LoginID As ADODB.Parameter, Entity_Id As ADODB.Parameter

Application.ScreenUpdating = False

Set Conn = New ADODB.Connection
Set RecordSet = New ADODB.RecordSet
Set Command = New ADODB.Command

'w
RecordSet.CursorType = adOpenStatic
RecordSet.CursorLocation = adUseClient


ConnectionString = "Provider=SQLOLEDB;Data Source=HIQARBL218\SQLEXPRESS;Initial Catalog=SweSalaryStore;Trusted_Connection=yes;"

On Error GoTo CloseConnection

Conn.Open ConnectionString

StoredProcName = "dbo.getInfoFromSQLDB"

With Command
    .ActiveConnection = Conn
    .CommandType = adCmdStoredProc
    .CommandText = StoredProcName
End With

Set EMPNR = Command.CreateParameter("@EMPNR", adVarChar, adParamInput, 100, "107")
Command.Parameters.Append EMPNR

Set PERNR = Command.CreateParameter("@PERNR", adVarChar, adParamInput, 100, "1111110008")
Command.Parameters.Append PERNR

Set CMPNR = Command.CreateParameter("@CMPNR", adVarChar, adParamInput, 100, "5612")
Command.Parameters.Append CMPNR

Set PERIODFROM = Command.CreateParameter("@PERIODFROM", adVarChar, adParamInput, 100, "1001")
Command.Parameters.Append PERIODFROM

Set PERIODTO = Command.CreateParameter("@PERIODTO", adVarChar, adParamInput, 100, "1701")
Command.Parameters.Append PERIODTO

Set RecordSet = Command.Execute


Sheets("Sheet1").Range("A5").CopyFromRecordset RecordSet


'loop to get column headings.
For i = 0 To RecordSet.Fields.Count - 1
    Sheets("Sheet1").Cells(1, i + 1).Value = RecordSet.Fields(i).Name
Next i


'Calculate last row in RecordSet
Dim lastRow As Integer
lastRow = 2000
'lastRow = RecordSet.RecordCount 'NOT WORKING!!!

'Average OB
Dim AvgOB As Double
AvgOB = Excel.WorksheetFunction.Average(Range(Sheets("Sheet1").Cells(5, 2), Sheets("Sheet1").Cells(lastRow, 2)))
AvgOB = Excel.WorksheetFunction.Round(AvgOB, 2)
Sheets("Sheet1").Cells(2, 2).Value = AvgOB
Sheets("Sheet1").Cells(3, 2).Value = AvgOB * 12


RecordSet.Close
Conn.Close
On Error GoTo 0
Application.ScreenUpdating = True
Exit Sub

CloseConnection:
    Application.ScreenUpdating = True
    MsgBox "SQL Stored Procedure Did Not Execute Sucessfully!", vbCritical, "SQL Error"
    Conn.Close

End Sub

Answer 1

You've done

 Sheets("Sheet1").Range("A5").CopyFromRecordset RecordSet  

so at that point the number of records returned is the number of rows occupied from a5 down:

 Dim lastrow as long  'not integer!
 lastrow = Sheets("Sheet1").Range("A5").currentregion.rows.count + 4

the plus four is since you start at row 5