在ASP Classic / VBscript中比较时间

Question

I am working on a function for an asp page that compares if a time entered is greater than a time with added leeway. I noticed certain times when checked would fail the test when the times are equal. Included is a snip of my function to illustrate. Not sure why equal dates would fail, and would like to know if this is a good way to go about comparing time.

<% 


function TimeTest(testTime, checkTime, buffer, try)

checkingTime = FormatDateTime(cdate(DateAdd("n", buffer, cdate(checkTime))),4)


if try = 1 then
testTime = FormatDateTime(testTime, 4)
checktime = FormatDateTime(checkTime, 4)
end if

if cdate(testTime) > DateAdd("n", buffer, cdate(checkTime)) then
    TimeTest = "<p class = 'redS'>Fails! testTime: "&testTime&"  < checkTime:"&checkingTime&"</p>" 
else
    TimeTest = "<p class = 'greenS'>Works! testTime: "&testTime&"  > checkTime:"&checkingTime&"</p>"
end if 


end function


response.write("<br><br><h1>Test2</h1><br>")

for i=0 to 23
    for j=0 to 59

    response.write(TimeTest(i&":"&j&":00", i&":00:00", j, 1))
    response.write("<BR>")

    next
next

%> 

Answer 1

This problem has earned my attention! I can reproduce the results and it's very unclear what's going on behind the scenes in these comparisons. However, I have a workaround for you

Here is a modified version of the code that I've been using to analyse the issue...

<% 

Option Explicit

Function TimeTest(a, b, buffer)
    Dim c : c = DateAdd("n", buffer, b)

    Dim s : s = Join(Array("a=" & a, "b=" & b, "c=" & c, "buffer=" & buffer), ", ")

    Dim passed : passed = a <= c
    'Dim passed : passed = DateDiff("s", a, c) <= 0

    If passed Then Exit Function

    Dim color : color = "red" : If passed Then color = "green"
    TimeTest = "<div style='color:" & color & "'>" & s & "</div>" 
End Function

Dim i, j, a, b
For i = 0 To 23
    For j = 0 To 59
        a = CDate(i & ":" & j & ":00")
        b = CDate(i & ":00:00")
        'a = CDate(Date() & " " & i & ":" & j & ":00")
        'b = CDate(Date() & " " & i & ":00:00")
        Response.Write(TimeTest(a, b, j))
    Next
    Response.Write("<hr>")
Next

%> 

Note that commenting out line 13 will reveal lines that pass. By default, I'm showing only failures.

The first thing to note is that I have some commented variants on lines 24-25 where I add today's date to the value before casting it. Interestingly, doing this changes the pattern of which times fail the test. There are still roughly the same number of failures but they occur at different buffer values.

This leads me to believe that behind the scenes in VBScript, these datetimes might be cast to floating-point numbers when you use the native < <= > >= comparison operators on them and that's resulting in some precision errors. If they were converted to long integers, then they should surely be correct.

I did a version of the code where instead of using a direct comparison on the VBDateTimes, I compared the integer representation of them (unix time) using this function :

Function date2epoch(myDate)
    date2epoch = DateDiff("s", "01/01/1970 00:00:00", myDate)
End Function

When doing that, all tests passed. However, it is an unusual way to do things. I thought there should be a more 'normal' way.

I then went back and replaced the straightforward <= operator with a call to DateDiff instead (comment out line 10, uncomment line 11). Whether I used seconds or minutes, the tests passed. So, I think the takeaway lesson here might be to always use DateDiff when comparing VBDateTimes. As someone who's used VBS for a while and never encountered issues with native comparisons before, this is a revelation and I may need to offer this advice to my colleagues too.