如何获取节点的内容并保留内部标签

Question

Using XSLT, given something like this:

<summary>
    Blah, blah, blah <code>foo</code> blah <code>bar</code> blah.
</summary>

How would you transform it into something like:

<div>
    Blah, blah, blah <code>foo</code> blah <code>bar</code> blah.
<div>

I started out, in my XSLT, with something like:

<div>
    <xsl:value-of select="summary"/>
</div>

But this will transform into:

<div>
    Blah, blah, blah foo blah bar blah.
<div>

In other words, I lost the inner <code> . I then tried

<div>
    <xsl:copy-of select="summary"/>
</div>

But that'll give me:

<div>
    <summary>
        Blah, blah, blah <code>foo</code> blah <code>bar</code> blah.
    </summary>
</div>

In other words, the <summary> tag that I aimed to replace is included.

Then I started getting creative:

<xsl:copy-of select="summary/*"/>

Only outputs the contents of the <code> tags

<xsl:copy-of select="summary/text()"/>

Removes the <code> tags and their contents entirely.

So is there a way to make this work? Select the contents of the summary tag (without the summary tag itself) and preserve any inner tags?

Answer 1

If you want to transform the summary element into a div then write a template doing that

  <xsl:template match="summary">
      <div>
          <xsl:apply-templates/>
      </div>
  </xsl:template>

Then you only need to make sure the rest is copied unchanged which you can do in XSLT 3 ( http://xsltfiddle.liberty-development.net/eiQZDba ) with

  <xsl:mode on-no-match="shallow-copy"/>

or in earlier versions by spelling out the identity transformation as a template

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

Answer 2

Use an identity template and a replace template with xsl:apply-templates inside like this:

<!-- identity template - copies all nodes -->
<xsl:template match="node()|@*">
  <xsl:copy>
    <xsl:apply-templates select="node()|@*" />
  </xsl:copy>
</xsl:template>

<!-- replace template - more specific element template -->
<xsl:template match="summary">
  <div>
    <xsl:apply-templates select="node()|@*" />
  </div>
</xsl:template>

Result:

<div>
    Blah, blah, blah <code>foo</code> blah <code>bar</code> blah.
</div>