如何在不打开 Android Studio 的情况下打开 AVD Manager GUI？

Question

As I'm not developing my app with Android Studio, but I'm still using the Android emulator.

What's a nice way for me start up my emulator without doing this?

1. Open Android Studio
2. Open some project
3. Click the AVD Manager button

I'm not looking for a complete CI replacement, but if there's a long command I can run to open the GUI I'm happy.

Answer 1

Cd to your Android SDK location using PowerShell

cd C:\Users\UserName\AppData\Local\Android\Sdk\tools

and type

.\emulator.exe -list-avds

this will show your available avds, choose your device copy the name and replace the following

.\emulator.exe -avd "<virtualDeviceName>"

Eg:

.\emulator.exe -avd "Pixel_2_API_27"

You can simply create a .bat file

@echo off
cd C:\Users\UserName\AppData\Local\Android\Sdk\tools
@echo Running the emulator
.\emulator.exe -avd "Pixel_2_API_27"

Answer 2

What about a script that show current avds defined and let you choose which one start ? I called it avdmanager.bat in root of SDK (variable ANDROID_HOME set on SDK root needed):

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
SET count=0
FOR /F "tokens=* USEBACKQ" %%F IN (`%ANDROID_HOME%\emulator\emulator.exe -list-avds`) DO (
  SET /a count=!count!+1
  SET var!count!=%%F
)
for /l %%i in (1,1,%count%) do echo %%i) !var%%i!
@echo digit number of virtual machine to run or 'q' to quit
set /p choice=""
if "%choice%"=="q" goto end
@echo !var%choice%!
%ANDROID_HOME%\emulator\emulator.exe -avd !var%choice%!
:end
ENDLOCAL

Answer 3

Just a minor fix with the command -list-avds in @alrama's answer (the extra space), I cannot add comments yet.

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
SET count=0
FOR /F "tokens=* USEBACKQ" %%F IN (`%ANDROID_HOME%\emulator\emulator.exe -list-avds`) DO (
  SET /a count=!count!+1
  SET var!count!=%%F
)
for /l %%i in (1,1,%count%) do echo %%i) !var%%i!
@echo digit number of virtual machine to run or 'q' to quit
set /p choice=""
if "%choice%"=="q" goto end
@echo !var%choice%!
%ANDROID_HOME%\emulator\emulator.exe -avd !var%choice%!
:end
ENDLOCAL