启用编辑VBA

Question

I am working in Excel 2016. I currently created a macro that will loop through all open workbooks and grab the data in them if they start with the word "report". The issue I am trying to solve now is how to enable editing. If the users enable editing after downloading all reports to be combined there is no issue with the macro. They run into issues with the macro not grabbing the data if they missed that button.

While they are not working with that many workbooks, I am trying to make it easier for them. The code that I have posted will do the first 3 workbooks and then continue looping through the remaining 5 but will not "Enable Edit".

 Sub EnableEdit()

 Dim bk As Workbook
 Dim w As Long, wCount As Long

 wCount = Application.ProtectedViewWindows.Count
 Set wsh = ThisWorkbook.Worksheets("Data")

 On Error Resume Next
    If wCount > 0 Then
        For w = 1 To wCount
            Application.ProtectedViewWindows(w).Activate
            Application.ProtectedViewWindows(w).Edit

            If Left(ActiveWorkbook.Name, 6) = "report" Then
                ActiveWorkbook.Worksheets(1).Range("A1:Z1").Copy _
                    Destination:=wsh.Range("A1")
                nrow = wsh.Cells(Rows.Count, 1).End(xlUp).Row + 1
                ActiveWorkbook.Worksheets(1).Range("A2:Z500").Copy _
                    Destination:=wsh.Range("A" & nrow)
                ActiveWorkbook.Close
            End If
        Next w
    End If
 On Error GoTo 0

 End Sub

Answer 1

Application.ProtectedViewWindows appears to be a collection of all the protected-view windows. As soon as you execute the .Edit method on one of those protected-view windows it is no longer in protected-view mode and is therefore removed from the collection.

This means that when you Edit the first member of the collection (when w is 1 ), what was the second member now becomes the first member, what was the third member now becomes the second, etc. And then on the next iteration of your loop (when w is 2 ) your code is therefore looking at the original third member, having completely ignored looking at the original second member.

The easiest way to fix the issue is to loop through the array in reverse order, ie use:

For w = wCount To 1 Step -1