如何序列化以在F＃上使用JSON.NET流？

Question

I need to send JSON to WebResourceResponse :

override this.ShouldInterceptRequest(view:WebView, request:IWebResourceRequest) =
    let rows = Customer.fakeData 1 // Array of records

    let st = Shared.jsonToStream(rows)
    new WebResourceResponse("application/javascript", "UTF-8", st)

But don't see how do that. I use Json.NET and F#.

When I run:

let jsonToStream(value:'T) =
    let serializer = new JsonSerializer()
    let std = new IO.MemoryStream()
    let sw = new IO.StreamWriter(std)
    let json = new JsonTextWriter(sw)
    serializer.Serialize(json, value)
    //std.Position <- 0L
    std

the response returns as a blank string.

Answer 1

You have the following issues:

1. You need to dispose of your StreamWriter and JsonTextWriter so that the serialized JSON is flushed to the underlying stream. This can be done by replacing let with use .

   However, you need to do so without closing the underlying stream std , since you are going to read from it later.

2. Having done so, you need to reset the position of the std stream after sw and json have gone out of scope and been disposed. If you try to reset the position before then it won't work.

Thus the following will work:

let jsonToStream(value:'T) =
    let serializer = new JsonSerializer()
    let std = new IO.MemoryStream()
    (   use sw = new StreamWriter(std, new UTF8Encoding(false, true), 1024, true)
        use json = new JsonTextWriter(sw, CloseOutput = false)
        serializer.Serialize(json, value))
    std.Position <- 0L
    std

Note the use of parentheses to restrict the scope of sw and json so that std.Position can be reset after they go out of scope. jsonToStream(rows) will now return an open MemoryStream containing complete, serialized JSON and positioned at the beginning.

Sample working f# fiddle .