如何将该功能添加到蝙蝠聊天机器人中？

Question

This is my chatbot. I would like to add that if the input is something different than "yes" and "no" then it should echo "Wrong answer".

@ECHO OFF
title Bane
:CHAT
SET /P input=Oh You think darkness is your ally? (yes or no) Your message:

IF %input%==yes ECHO That's were you're wrong!
IF %input%==no ECHO Admirable, but mistaken.
GOTO CHAT
:END
PAUSE

Answer 1

@ECHO OFF
title Bane
:CHAT
SET /P "input=Oh You think darkness is your ally? (yes or no) Your message: "
IF /i "%input%"=="yes" ECHO That's were you're wrong! & goto :end
IF /i "%input%"=="no" ECHO Admirable, but mistaken. & goto :end
echo wrong answer & goto :chat

:END
PAUSE

you might be interested in the choice command, which has it's own input verification:

@ECHO OFF
title Bane
:CHAT
choice /C YN /M "Oh You think darkness is your ally? Your message: "
if errorlevel 2 ECHO That's were you're wrong! & goto :end
if errorlevel 1 ECHO Admirable, but mistaken. & goto :end
echo wrong answer ; this line is never reached

:END
PAUSE

In the second code example I removed (yes or no) , as choice already prints out all valid choices. But of course you can keep it and supress default choices wihth /n (thanks, Compo, valid argument):

`choice /C YN /N /M "Oh You think darkness is your ally? (yes or no) Your message: "`