在vba的单个子/函数中可以使用多少个变量？

Question

I have built a simple function but it needs around 11-12 variable that have the same integer type. Every time I tried to used with more than 10 variables, the first one often gets wrong while the others are correctly calculated. If I reduce the number of variables down to 10, they they are all correct. Does it mean hat vba can only store 10 variables with the same type at a time? Or it is my computer' limit :))

This is my code, btb return the wrong value while the others is correct, but if I delete variable "a" and all the code related to it, then btb return correctly

Sub regionCount()
Dim btb, dbb, hn, ntb, dnb, tnbBS, tnbNS, hcm1, hcm2, hcm3, a As Integer

btb = dbb = hn = dnb = tnbBS = tnbNS = hcm1 = hcm2 = hcm3 = a = 0

For Each mycell In Worksheets(1).Range("E2:E382")
    If mycell.Value = "Khu vuc Bac Trung Bo" Then
        btb = btb + 1
    ElseIf mycell.Value = "Khu vuc Dong Bac Bo" Then
        dbb = dbb + 1
    ElseIf mycell.Value = "Khu vuc Ha Noi" Then
        hn = hn + 1
    ElseIf mycell.Value = "Khu vuc Nam Trung Bo" Then
        ntb = ntb + 1
    ElseIf mycell.Value = "Khu vuc Dong Nam Bo" Then
        dnb = dnb + 1
    ElseIf mycell.Value = "Khu vuc Tay Nam Bo  - Bac song hau" Then
        tnbBS = tnbBS + 1
    ElseIf mycell.Value = "Khu vuc Tay Nam Bo  - Nam song hau" Then
        tnbNS = tnbNS + 1
    ElseIf mycell.Value = "Khu vuc TPHCM_1" Then
        hcm1 = hcm1 + 1
    ElseIf mycell.Value = "Khu vuc TPHCM_2" Then
        hcm2 = hcm2 + 1
    ElseIf mycell.Value = "Khu vuc TPHCM_3" Then
        hcm3 = hcm3 + 1
    ElseIf mycell.Value = "-- None --" Then
        a = a + 1
    End If
Next mycell

Range("C5").Value = btb
Range("d5").Value = dbb
Range("e5").Value = hn
Range("f5").Value = ntb
Range("g5").Value = dnb
Range("h5").Value = tnbBS
Range("i5").Value = tnbNS
Range("j5").Value = hcm1
Range("k5").Value = hcm2
Range("l5").Value = hcm3
Range("m5").Value = a

End Sub

Answer 1

Your statement

btb = dbb = hn = dnb = tnbBS = tnbNS = hcm1 = hcm2 = hcm3 = a = 0

should be

btb = 0
dbb = 0
hn = 0
dnb = 0
tnbBS = 0
tnbNS = 0
hcm1 = 0
hcm2 = 0
hcm3 = 0
a = 0

---

Consider the statement

a = b = c

That is interpreted as

a = (b = c)

where (b = c) is a logical expression. So, if b is the same value as c (which it will be if the variables have all been left to the default initialisation of 0 ) then a will be set to True (ie -1 )

The way you had your statement laid out would have set the value on the very left to be -1 (if you had an odd number of variables in the line) or to 0 (if you had an even number).

---

It should also be noted that

Dim btb, dbb, hn, ntb, dnb, tnbBS, tnbNS, hcm1, hcm2, hcm3, a As Integer

is equivalent to

Dim btb As Variant, dbb As Variant, hn As Variant, ntb As Variant, dnb As Variant, _
    tnbBS As Variant, tnbNS As Variant, hcm1 As Variant, hcm2 As Variant, _
    hcm3 As Variant, a As Integer

It is not the same as

Dim btb As Integer, dbb As Integer, hn As Integer, ntb As Integer, dnb As Integer, _
    tnbBS As Integer, tnbNS As Integer, hcm1 As Integer, hcm2 As Integer, _
    hcm3 As Integer, a As Integer

Answer 2

A single project can contain up to 32,000 "identifiers" (any nonreserved keyword), which include, but are not limited to, forms, controls, modules, variables, constants, procedures, functions, and objects. Note that the actual number of identifiers is limited to available memory.

Variable names in Visual Basic can be no longer than 255 characters, and the names of forms, controls, modules, and classes cannot be longer than 40 characters. Visual Basic imposes no limit on the actual number of distinct objects in a project.

Code Limitations

The amount of code that can be loaded into a form, class, or standard module is limited to 65,534 lines. A single line of code can consist of up to 1023 bytes. Up to 256 blank spaces can precede the actual text on a single line, and no more than twenty-four line-continuation characters ( _) can be included in a single logical line.

Procedures, Types, and Variables There is no limit on the number of procedures per module. Each procedure can contain up to 64K of code. If a procedure or module exceeds this limit, Visual Basic generates a compile-time error. If you encounter this error, you can avoid it by breaking extremely large procedures into several smaller procedures, or by moving module-level declarations into another module.

Visual Basic uses tables to store the names of identifiers (variables, procedures, constants, and so on) in your code. Each table is limited to 64K.

DLL Declare Table Each form and code module uses a table that contains a structure describing a DLL entry point. Each structure uses approximately 40 bytes, with a total restricted size of 64K, resulting in roughly 1,500 declarations allowed per module.

Project-Name Table The entire application uses a single table that contains all names. These include:

Constant names

Variable names

User-defined — type definition names

Module names

DLL-procedure declaration names The project name table is unlimited in total size, but is limited to a total of 32K case-sensitive unique entries. If the limit is reached, reuse private identifiers in different modules to limit the number of unique entries to 32K.

Import Table Every reference to an identifier in a different module creates an entry in the Import Table. Each such entry is a minimum of 24 bytes and is restricted to 64K, resulting in roughly 2,000 references per module.

Module-Entries Table This table accepts up to 125 bytes per module, with a total limit of 64K, resulting in about 400 modules per project.

The following limitations apply to variables in the Visual Basic language.

Form, Standard, and Class Module Data The data segment (that is, the data defined in the Declarations section) of the VBA module of any form or module in Visual Basic can be up to 64K. This data segment contains the following data:

Local variables declared with Static.

Module-level variables other than arrays and variable-length strings.

4 bytes for each module-level array and variable-length string. Procedures, Types, and Variables If a procedure or module exceeds the 64K code limit, Visual Basic generates a compile-time error.

If you define a procedure that has more than 64K of local variables defined, you get the error "Too many local nonstatic variables."

If you define a module that has more than 64K of module-level variables defined, or if you define a User-Defined Type larger than 64K, you get the error "Fixed or static data can't be larger than 64K."

If you encounter this error, you can avoid it by breaking extremely large procedures into several smaller procedures, or by moving module-level declarations into another module.

An array declared as a variable doesn't contribute to the entire size of the array; only the array descriptor counts toward the 64K limit. So it is acceptable, for example, to have a declaration such as Dim x(1000000) As Byte either in a procedure or at module level. Out of memory problems occur, however, if you declare a large, fixed-size array in a record, then declare instances of those records as variables.

User-Defined Types No variable of a user-defined type can exceed 64K, although the sum of variable-length strings in a user-defined type may exceed 64K (variable-length strings occupy only 4 bytes each in the user-defined type; the actual contents of a string are stored separately). User-defined types can be defined in terms of other user-defined types, but the total size of the types cannot exceed 64K.

Stack Space Arguments and local variables in procedures take up stack space at run time. Module-level and static variables do not take up stack space because they are allocated in the data segment for forms or modules. Any DLL procedures you call use this stack while they are executing.

Visual Basic itself uses some of the stack for its own purposes, such as storing intermediate values when evaluating expressions.

Total available stack size for Visual Basic is one megabyte (1MB) per thread. A stack may grow beyond this, however, if there is adjacent free memory.

For More Information For tips on conserving stack space, see "Designing for Performance and Compatibility."

From https://msdn.microsoft.com/en-us/library/aa716295(v=vs.60).aspx ‎ and nearby pages.

Answer 3

There are at least two things wrong with your code:

1. Declaration is incorrect

    Dim btb, dbb, hn, ntb, dnb, tnbBS, tnbNS, hcm1, hcm2, hcm3, a As Integer 

   Multiple declarations on a single line are allowed, but each variable needs its own As part. Currently, only a is declared as Integer , the others will be Variant . Change to:

    Dim btb As Integer, dbb As Integer, hn As Integer, ntb As Integer, dnb As Integer, tnbBS As Integer, tnbNS As Integer, hcm1 As Integer, hcm2 As Integer, hcm3 As Integer, a As Integer 

2. Multiple assignments on a single line are not allowed, only the first one is performed. So in this case:

    btb = dbb = hn = dnb = tnbBS = tnbNS = hcm1 = hcm2 = hcm3 = a = 0 

   only the value of btb is changed to False as

    dbb = hn = dnb = tnbBS = tnbNS = hcm1 = hcm2 = hcm3 = a = 0 

   evaluates to False .