groovy：拆分字符串但包含定界符

Question

I want to split a string about a delimiter, but I want the delimiter to be included in the output. For example:

> String s = "helloXthereXmyXfriend"
> s.split("X")
["hello","Xthere","Xmy","Xfriend"]

Is there a method that does this, or do I need to write my own?

Answer 1

Here is a method that works

String[] split(String s, String regex) {
    String[] split = s.split(regex);
    String[] out = Arrays.stream(split)
        .map(x -> regex + x)
        .toArray(String[]::new);
    out[0] = split[0];
    return out;
}

Answer 2

I don't know of a method that does this, but you could use meta-programming to add your own:

String.metaClass.splitInclude { delimiter ->
    def tokens = delegate.split(delimiter) as List
    def result = tokens.withIndex().collect { item, index ->
                    (index) ? "${delimiter}${item}" : item 
                 } 
}

def s = "helloXthereXmyXfriend"
def result = s.splitInclude('X')
assert ["hello","Xthere","Xmy","Xfriend"] == result

Answer 3

There is no need for post-processing by Groovy code. Regex has enough power to do the task on its own. Try this regex:

.+?(?=X|$)

How it works:

• .+? - Match non-empty sequence of characters, as little as possible.
• (?=X|$) - Positive lookup: After what you have just matched there is either X (your pattern) or the end of the string.

In Groovy the task is now not to split the source string, but find all matches.

Try this code:

String s = "helloXthereXmyXfriend"
def tbl = s.findAll('.+?(?=X|$)')
print tbl

Note that I changed double quotes around the regex to single quotes, to prevent interpolation of variables.

It prints:

[hello, Xthere, Xmy, Xfriend]