当我的 Windows.bat 被调用时，ECHO 是打开还是关闭？

Question

When I CALL one Windows .bat file from another, can the called file tell whether ECHO was ON or OFF in the caller?

When a .bat file is entered, ECHO is set to ON (even if it was OFF in the CALLER).

I want to preserve the caller's ECHO status in the called .bat so I can control both (possibly a chain of more than two nested calls) from a single place.

I could pass a parameter or set my own environment variable but is there a better way?

EDIT Just to clarify what's needed: callee.cmd needs to do things with echo off only for the duration of its run. Upon returning to its caller, it must restore the echo state the caller had.

Please fill in the?????s in the script below:

callee.cmd:

@rem save the echo state
@ ???? HOW???? ????
@ set "savedEchoState=??????"

@rem the following commands must not be echoed
@echo off
command1
command2
command3

@rem restore the previous echo state
echo %savedEchoState%

caller1.cmd:

@echo off
call callee.cmd
echo

caller2.cmd:

@echo on
call callee.cmd
echo

Required output:

caller1.cmd must print echo off and caller2.cmd must print echo on .

Can it be done without creating any files on a disk ?

Answer 1

This is a tough one. Everything involving a pipe or a for doesn't work, as new processes get generated, which invalidates the echo status. It is possible involving a temp file:

A.BAT:

echo on
echo
call b.bat
echo off
echo
call b.bat
echo

B.BAT:

@(>tmp echo)
@type tmp|find "ON" >nul && (@set "oldEcho=ON") || (@set "OldEcho=OFF")
@echo off
echo B:echo was previously %OldEcho%
REM insert your payload here
REM restore previous Echo Status:
echo %OldEcho%

Result:

C:\Folder>a

C:\Folder>echo on

C:\Folder>echo
ECHO ist eingeschaltet (ON).

C:\Folder>call b.bat
B:echo was previously ON

C:\Folder>echo off
ECHO ist ausgeschaltet (OFF).
B:echo was previously OFF
ECHO ist ausgeschaltet (OFF).

Answer 2

To detect the ECHO state without dependency to the windows language you could use a temporary file.
The file is empty when ECHO is OFF, else it contains the language string of ECHO IS ON .

@echo off
echo Testing detectEchoState

echo on
@call :detectEchoState

@echo off
@call :detectEchoState off
exit /b


:detectEchoState
@(
    (
        FOR /F %%L in ("1") do REM
    ) > "%TEMP%\echoCheck.tmp"

    FOR /F "delims=" %%F in ("%TEMP%\echoCheck.tmp") do @if %%~zF == 0 (set "EchoState=OFF" ) ELSE (set "EchoState=ON")
    del "%TEMP%\echoCheck.tmp"
    echo EchoState !EchoState!
)
@exit /b

Answer 3

I had the same problem, and ended up on this page.
Here's a slightly improved version of jeb's script.

• It uses (call,) instead of rem, which avoids having to put the ) on a separate line.
• It does not depend on delayed expansion being on for the testing.

@echo off
call :TestEchoState off
call :TestEchoState on
exit /b

:TestEchoState %1=ON or OFF
echo %1
@echo
@call :GetEchoState STATE
@echo off
echo STATE=%STATE%
exit /b

:GetEchoState %1=OUTVAR
@for /f %%F in ("%TEMP%\EchoState%PID%.tmp") do @(
  (FOR /f %%N in ("1") do call,) > "%%F"
  for %%S in ("%%F") do @if %%~zS==0 (set "%1=OFF") else (set "%1=ON")
  del "%%F"
)
@exit /b

And if you accept to just test the errorlevel, it's possible to make the detection routine even shorter:

@echo off
call :TestEchoLevel off
call :TestEchoLevel on
exit /b

:TestEchoLevel %1=ON or OFF
echo %1
@echo
@call :GetEchoLevel
@echo off
if errorlevel 1 (echo STATE=ON) else (echo STATE=OFF)
exit /b

:GetEchoLevel # Returns errorlevel 0 if echo is off
@for /f %%F in ("%TEMP%\EchoLevel%PID%.tmp") do @(
  (for /F %%N in ("1") do call,) > "%%F"
  for %%S in ("%%F") do @del "%%F" & exit /b %%~zS
)

Answer 4

( Editing the answer from Stephan , considering the echo state can be also reported in lower case, and that his answer does not allow for edition. )

The first 2 lines and the last one below save and restore the echo state. The lines 3 to 6 should be replaced by your code:

@(>tmp echo)
@type tmp|find /i "ON" >nul && (@set "oldEcho=ON") || (@set "OldEcho=OFF")
    @echo off                               &::line 3
    echo B:echo was previously %OldEcho%    &::line 4
    REM insert your payload here            &::line 5
    REM restore previous Echo Status:       &::line 6
echo %OldEcho%