如何从SAS中设置的日期获取系列的最后一个非空列

Question

I'm working on a SAS application and I've a data set as

dim_point
rk | ID    | name  | value_0 | value_1 | value_2 | value_3 | value_4
1  | one   |  one  |  val_0  |  val_1  |  val_2  |  val_3  |   .
2  | two   |  two  |  val_0  |  val_1  |  val_2  |    .    |   .
3  | three | three |  val_0  |    .    |    .    |    .    |   .
4  | four  | four  |  val_0  |  val_1  |    .    |    .    |   .

I want to get other columns and last non empty column of value as

want
rk | ID    | name  |  value
1  | one   |  one  |  val_3
2  | two   |  two  |  val_2
3  | three | three |  val_0
4  | four  | four  |  val_1

code that I'm trying to do is

proc sql noprint;
create table want as
select rk, ID, name, name as value
from dim_point;

update want 
set value = "";
quit;

I don't know how I can update value column with last non empty column value of value_ series?

Answer 1

Use coalesce in reverse order:

set value = coalesce(value_4,value_3,value_2,value_1,value_0);

You might need to use coalescec instead for character variables.

Answer 2

Whilst the coalesce solution is fine when you know all the columns, there may be situations where they can either vary, or are significantly more of them.

In that case, you can use an array :

data want ;
  set have ;
  array _v{*} value_: ; /* colon operator is a wildcard, loaded in the same order as the input dataset */

  /* Loop backwards over the array, stop when we find a non-missing value */
  do i = dim(_v) to 1 by -1 until (not missing(value)) ;
    if not missing(_v{i}) then value = _v{i} ;
  end ;

  drop i ;
run ;