等效于SAS的SQL验证字符串数据

Question

I'm trying to validate some alphanumeric data of length 6 and I have a working piece of code in SQL to do this, but I'm struggling with how to code this in SAS as a calculated column in my query.

In SQL a valid string in my data meets the following criteria:

CASE 
   WHEN <String> LIKE '[a-z][0-9][a-z][0-9][a-z][0-9]' 
      THEN 'Valid'
      ELSE 'Invalid' 
END

What functions can I use in SAS that will achieve this? I'm using SAS EG as my tool.

Thanks!

Answer 1

Assuming you are asking about writing this as SAS code, this can be done any number of ways. The most similar that you can do is to use Perl regular expressions; I don't think LIKE in SAS supports regex syntax (despite [ being a special character), or at least the documentation doesn't mention it as possible and I couldn't get it to work.

data have;
length charvar $6;
  input charvar $;
  datalines;
a1b2c3
1A2B3C
AAAAAA
111111
C3B2A1
;;;;
run;

proc sql;
select charvar, 
CASE 
   WHEN prxmatch('/[a-z][0-9][a-z][0-9][a-z][0-9]/i',charvar)
      THEN 'Valid'
      ELSE 'Invalid' 
END
from have;
quit;

You could do the same thing in a SAS datastep, or a number of other things that would work just as well.

Answer 2

You could also consider using FIND( string to be searched , string you're looking for ).

http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a002267763.htm

The FIND function searches string for the first occurrence of the specified substring, and returns the position of that substring. If the substring is not found in string, FIND returns a value of 0.

So long as your FIND() returns a number greater than 0, you'll know that you have a match in there.

Answer 3

I think Joe's answer using Perl regular expressions with prxmatch() is the best approach to this problem. However, to demonstrate SAS macros and string functions, here's an alternative.

In this approach, each character is checked in turn. substr(,&pos,1) isolates the character, and compress(,,'xk') deletes the character if it is not of the correct type (specified by whether 'x' is 'a' or 'd'). Applying the lengthn() function returns 1 if the character is of the correct type and 0 otherwise. Note that length() will not work, because it would return 1 for an empty string. Then, 'Valid' is assigned if all characters are of the correct type.

data have;
    length charvar $6;
    input charvar $;
    datalines;
a1b2c3
1A2B3C
AAAAAA
111111
C3B2A1
;
run;

* invar is the variable, pos is the position of the letter being checked, type is be d for digits or a for letters;
%macro check(invar, pos, type) ;
    (1 = lengthn(compress(substr(&invar, &pos, 1), , "&type.k")))
%mend  ;

data validation ;
    set have ;
    length validation $7 ;
    if %check(charvar, 1, a) & %check(charvar, 2, d) & %check(charvar, 3, a) & 
       %check(charvar, 4, d) & %check(charvar, 5, a) & %check(charvar, 6, d)
        then validation = 'Valid' ;         
        else validation = 'Invalid' ;       
run ;
dm 'vt validation';