Clojure [Script]中的…rest for maps相当于什么？

Question

I can do map destruction like the following in JavaScript:

const drop = (key, obj) => {
  const { [key]: _, ...rest } = obj;
  return rest;
}

drop('name', { name: 'book', chapters: 12 }); // => { chapters: 12 }

How can I do ...rest / & rest for maps in Clojure[Script]?

Answer 1

There is no equivalent destructuring like that for maps in Clojure. I think effectively you're looking for dissoc if you just want to omit map entries by key:

(dissoc {:name "book" :chapters 12}
        :name)
=> {:chapters 12}

There is rest destructuring for other sequence types:

(let [[x & xs] [1 2 3]]
  (prn x)   ;; "1"
  (prn xs)) ;; "(2 3)"

where xs (the part after & ) is the rest of the value.

There are several other options for map destructuring:

(def my-map {:name "book" :chapters 12 :extra "stuff"})
(let [{:keys [name chapters] :as m} my-map]
  (prn name)     ;; value of name key only
  (prn chapters) ;; value of chapters key only
  (prn m))       ;; the entire bound value
;; "book"
;; 12
;; {:name "book", :chapters 12, :extra "stuff"}

The use of :as in that destructuring example is probably the closest you'll get to the behavior you're seeing in JavaScript, except it doesn't exclude the explicitly destructured keys.

(let [{n :name} my-map]
  (prn n)) ;; the value of name key only, aliased

See this guide for more.