如何使用if-then语句创建活动/非活动状态并遍历所有行VBA / Excel

Question

I am trying to create a project management macros and I have coded many parts of it, but I am having trouble with the last piece below.

Each task has a start date (Column D), end date (Column E),and a status (Column K). My initial goal was to check if any of the days within "this week" would fall within the start date and end date for that particular row. I completed this goal and now I would like to loop this formula/code and create a status for every row based on the start date and end date for every individual row.

There are an infinite number of rows, because each project is different and I using this macros as a template.

Does anyone know how to loop this formula through each row until there are no more rows with data in them?

Thank you so much for your help in advance!

Sub PM_Schedule() 

'mark as active if this week falls within range D:E

Dim bk As Integer

    Application.ScreenUpdating = False

    ' Set numrows = number of rows of data.
    NumRows = Range("$D2", Range("$D2").End(xlDown)).Rows.Count

    ' Select cell D2.
    Range("$D2").Select

    ' Establish "For" loop to loop "numrows" number of times.
    For x = 1 To NumRows

    Dim D As Integer
    Dim N As Date

    D = Weekday(Now)
    Thismonday = Now() + (2 - D)
    ThisTuesday = Now() + (3 - D)
    ThisWednesday = Now() + (4 - D)
    ThisThursday = Now() + (5 - D)
    ThisFriday = Now() + (6 - D)

    StartDate = xWs.Range("$D2").Value
    EndDate = xWs.Range("$E2").Value

        If Thismonday >= StartDate And Thismonday <= EndDate Then
            Status = "Active"
        ElseIf ThisTuesday >= StartDate And ThisTuesday <= EndDate Then
            Status = "Active"
        ElseIf ThisWednesday >= StartDate And ThisWednesday <= EndDate Then
            Status = "Active"
        ElseIf ThisThursday >= StartDate And ThisThursday <= EndDate Then
            Status = "Active"
        ElseIf ThisFriday >= StartDate And ThisFriday <= EndDate Then
            Status = "Active"
        Else
            Status = "Not Active"
        End If

        xWs.Range("$K2").Value = Status

    Next

        ' Selects cell down 1 row from active cell.
          ActiveCell.Offset(1, 0).Select

      Next

      Application.ScreenUpdating = True

End Sub

Answer 1

Untested, but something like this should be close:

Sub PM_Schedule()

    'mark as active if this week falls within range D:E
    Dim xWS As Worksheet, c As Range
    Dim ThisMonday, ThisFriday, StartDate, EndDate, Status

    Set xWS = ActiveSheet
    ThisMonday = Date + (2 - Weekday(Date)) '<< use Date, not Now
    ThisFriday = ThisMonday + 4

    Application.ScreenUpdating = False

    'It's usually safer to use End(xlUp) than xlDown
    For Each c In xWS.Range(xWS.Range("D2"), _
                            xWS.Cells(xWS.Rows.Count, "D").End(xlUp)).Cells

        StartDate = c.EntireRow.Cells(4).Value 'D
        EndDate = c.EntireRow.Cells(5).Value   'E

        c.EntireRow.Cells(11).Value = IIf(StartDate <= ThisFriday And EndDate >= ThisMonday, _
                                        "Active", "Not active")
    Next
    Application.ScreenUpdating = True

End Sub