调试：如果不是 IsError() 那么

Question

I've set up the macro below which compares a column of codes (Instrument), one row at a time, by searching another column in a different workbook. If no code matches, the macro will alter a date in the first workbook by going back one day, which then changes the original code (in Instrument), and searches again. If a code is found, the macro should end by moving to the next row down:

Sub YTM()

    Dim N As Long
    N = Cells(5, 24).End(xlDown).Row
    'N = 7
    Dim c As Range
    Dim x As Integer

    For Each c In Range("X2:X" & N)
        c.Select
        If IsError(c) Then
            For x = 1 To 14
                ActiveCell.Offset(0, -18).Value = ActiveCell.Offset(0, -18).Value - x/x
                If Not IsError(c) Then Exit For
            Next x
        End If
    Next c

End Sub

However, my VBA discontinues and wants me to debug the following code:

If Not IsError(c) Then

I can't seem to work out why. I'm quite new to VBA, so I'm sure this issue is trivial. If further context is needed for clarity I am happy to oblige. All help is appreciated, thank you!

Answer 1

A bit more explicit about using Value , and without any Select/Activate:

Sub YTM()


    Dim N As Long, c As Range, x As Long

    N = Cells(5, 24).End(xlDown).Row

    For Each c In Range("X2:X" & N).Cells
        If IsError(c.Value) Then
            For x = 1 To 14
                 c.Offset(0, -18).Value = c.Offset(0, -18).Value - 1
                 DoEvents 'allow for calculation...
                 If Not IsError(c.Value) Then Exit For
            Next x
        End If
     Next c

End Sub